QuickTime - Film im Medienfeld von FM Pro über AS starten

[Ronny]

Hallo,

ich kann ja ein Medienfeld oder auch ein anderes über AS ansprechen, sprich zu dem Feld hin gehen (go do).
Jetzt muss ich aber in dem Medienfeld, nach diesem aktivieren, noch irgendwie die Abspieltaste aktivieren.
Ist das überhaupt irgendwie möglich.

Weiß nicht mehr weiter.

Gruß Ronny

[Snow]

Hallo Ronny,

einen Quicktime-Film kannst du durch Drücken der Leertaste starten.
Mit der Scripting Addition "Sändi's Additions" kannst du diese "Texteingabe" unter OS 9 simulieren.

tell application "FileMaker Pro"
activate
tell database "Testbase"
tell current record
go to cell "MeinMedium"
end tell
end tell
end tell

TypeText space

Und schon startet der Film. Unter OS X kannst du GUI Scripting zum Aktivieren benutzen - dann heißt der Befehl halt "keystroke space".
_________________
Peter
-
Fischer-Bayern.de|Shadetreemicro.com

[spirigwi]

[Snow]

Hallo Willy,

nur nichts durcheinander bringen. 'TypeText' entstammt der Scripting Addition 'Sändis Additions' und kann unter OS 9 zur Simulation einer Texteingabe benutzt werden. Findest du übrigens auf meiner Download-Seite.

Dadurch, dass man auch Modifier-Tasten wie z.B. Command, Shift, Capslock, Option und Control verwenden kann, ist es unter Umständen auch möglich, Menübefehle, die über einen Shortcut verfügen, ausführen zu lassen.

In OS X ist dies bereits ins System integriert und man braucht keine extra Scripting Addition. Diese Funktionalität nennt sich GUI-Scripting.

Um das GUI-Scripting anzuwenden, muss man in den Systemeinstellungen unter "Bedienungshilfen" den Punkt "Zugriff für Hilfsgeräte aktivieren" anhaken.

Ein typisches GUI-Script sieht dann etwa so aus:

set Stunde to "18"
set Minuten to "20"
set Sekunden to "00"


tell application "System Events"
    if (system attribute "sysv") < 4144 or UI elements enabled then
        tell application "System Preferences"
            activate
            set current pane to pane "com.apple.preference.datetime"
        end tell
        try
            tell process "System Preferences"
                tell window 1
                    tell tab group 1
                        -- Die richtige Registerkarte muss aktiv sein, also "Datum & Uhrzeit"
                        tell radio button 1
                            click
                        end tell
                        -- nur wenn die automatische Zeiteinstellung
                        -- per Server ausgeschaltet ist, kann man die Uhr
                        -- manuell einstellen
                        set TimeServerOn to value of checkbox 1 of group 1
                    end tell
                end tell
                if TimeServerOn = 0 then
                    delay 2
                    keystroke tab -- springt zum Tag
                    keystroke tab -- springt zum Monat
                    keystroke tab -- springt zum Jahr
                    keystroke tab -- springt zur Stunde
                    keystroke Stunde
                    keystroke tab
                    keystroke Minuten
                    keystroke tab
                    keystroke Sekunden
                    tell button 1 of group 1 of tab group 1 of window 1 -- "Einstellen"
                        click
                    end tell
                    keystroke "w" using command down
                    -- die Einstellungen werden nur übernommen, wenn man
                    -- den folgenden Dialog bestätigt.
                end if
            end tell
        end try
    else
        tell application "System Preferences"
            activate
            set current pane to pane "com.apple.preference.universalaccess"
            beep
            display dialog "GUI Scripting is not enabled." & return & return & "Check \"Enable access for assistive devices\" in the Universal Access preference pane (authentication is required), then run this script again." with icon stop buttons {"OK"} default button "OK"
        end tell
    end if
end tell


Dieses Skript stellt die Uhrzeit ein. Wenn du im Forum nach "GUI Scripting" suchst, wirst du es bestimmt nochmals finden. Zunächst wird mal festgestellt, ob GUI-Scripting funktioniert. Im Fehlerfall wird darauf hingewiesen, dass der Zugriff für Hilfsgeräte aktiviert sein muss.
Ist das GUI-Scripting möglich, wird per System Events erst mal dafür gesorgt, dass die zu skriptende Anwendung gestartet und in den Vordergrund geholt wird. Dann folgen Anweisungen, hierhin oder dorthin zu klicken, indem man die jeweiligen Elemente des User Interfaces anspricht und ihnen sagt, sie sollen einen click ausführen. Im obigen Beispiel sagt man dem Radio Button 1 der Tab Group 1 des Fensters 1 der Anwendung "System Preferences", dass die Aktion "click" ausgeführt werden soll, was auf die erste Registerkarte führt. Danach folgen auf dieser Registerkarte Texteingaben. Zuerst einmal ein paar Tabulatorschritte um zum Textfeld für die Stunde zu gelangen. Dann wird die Stunde eingegeben und per Tab geht's weiter zum Feld für die Minuten, weiter mit Tab zu Sekunden - es erfolgt jeweils die nötige Eingabe der Daten.
Zum Abschluss lassen wir noch den Buchstaben "W" tippen, wobei zusätzlich die Command- also Befehls- od. Apfeltaste zum Einsatz kommt. Und dieser Shortcut dient bekanntlich zum Schließen von Fenstern, was in unserem Fall die Anwendung "System Preferences" beendet.

Um die genaue Objekthierarchie eines Elements herauszufinden, benötigt man zwingend den "UI Elements Inspector", den es bei Apple kostenlos gibt. Man fährt dann mit der Maus über das fragliche Objekt und bekommt im UI Elements Inspector die Hierarchie angezeigt.
_________________
Peter
-
Fischer-Bayern.de|Shadetreemicro.com