Zeitumrechnung. Mache ich es richtig? - There is a Ringelspi

[Busyman]

Hallo!

Ich versuche gerade meinen Keynote Timer, bei dem mir Snow sehr geholfen hat, noch etwas zu verfeinern. Und selbstverständlich, wie immer: Es tauchen Fragen auf

1. Wie man unten, recht weit oben im Scriptcode, sieht, setze ich das Datum, an dem die Keynote stattfindet, in deutscher Sprache ein ("Donnerstag, 21. März 2002 0:00:00 Uhr"). Wenn ich das Script nun als Applet abspeichere, funktioniert es dann auch unter einem englischen OS? Denn ich kann in meinem Scripteditor das Datum nicht in Englisch eingeben, er formatiert das automatisch ins deutsche Format. Hintergrund: Ich möchte auch eine international verständliche Version des Keynote Timers veröffentlichen.

2. Womit wir gleich bei der zweiten Frage wären. Damit das Script in jeder Zeitzone funktioniert, muß ich ja eine feste Bezugsgröße hinslichtlich einer Zeit haben, da ist es praktisch, daß man bei AppleScript die Zeitdifferenz der Ortszeit zur GMT ermitteln kann (im Script: set gmtDifference to get (time to GMT)). Allerdings bin ich mir nicht im Klaren darüber, ob das so, wie ich es verwirklicht habe, auch funktioniert. Aber rein logisch denke ich, daß es funktionieren müßte, denn ich mache ja folgendes: Der Zeitpunkt der Keynote wird in Abhängigkeit zur GMT angegeben (keynoteDate). Dann ermittele ich die Ortszeit (current date) und die Abweichung der Ortsteit von der GMT (gmtDifference). Und um schließlich die Zeitdifferenz zur Keynote zu berechen, ziehe ich die GMT-Abweichung zur Ortszeit von der Ortszeit ab, um dann diese neu berechnete Ortszeit vom Zeitpunkt der Keynote abzuziehen. Au Mann, das hört sich komplizierter an, als es ist, hoffe nur, daß Ihr das auch versteht

Na gut, also das sind meine Probleme, vielleicht hat jemand einen guten Rat? Wäre fein

Euer Busyman



--••••• Properties •••••
property Steve : 12345

--••••• Script •••••
on run
my KeynoteTimer()
end run

on KeynoteTimer()
-- Beginn der Keynote umgerechnet in GMT (Greenwich Mean Time)
set keynoteDate to date "Donnerstag, 21. März 2002 0:00:00 Uhr"

-- aktuelle Ortszeit wird ermittelt und gespeichert
set actualDate to current date

-- Zeit-Differenz zur GMT wird ermittelt und gespeichert
set gmtDifference to get (time to GMT)


set timeDifference to (keynoteDate - (actualDate - gmtDifference))


-- Errechnung und Formatierung der Tage
set theDays to (timeDifference div 86400)
if theDays = 1 then
set dieTage to (theDays as string) & " Tag, "
else
set dieTage to (theDays as string) & " Tagen, "
end if

set secondsLeftA to (timeDifference mod 86400)

-- Errechnung und Formatierung der Stunden
set theHours to (secondsLeftA div 3600)
if theHours = 1 then
set dieStunden to (theHours as string) & " Stunde, "
else
set dieStunden to (theHours as string) & " Stunden, "
end if

set secondsLeftB to (secondsLeftA mod 3600)

-- Errechnung und Formatierung der Minuten
set theMinutes to (secondsLeftB div 60)
if theMinutes = 1 then
set dieMinuten to (theMinutes as string) & " Minute und "
else
set dieMinuten to (theMinutes as string) & " Minuten und "
end if

-- Errechnung und Formatierung der Sekunden
set theSeconds to (secondsLeftB mod 60)
if theSeconds = 1 then
set dieSekunden to (theSeconds as string) & " Sekunde."
else
set dieSekunden to (theSeconds as string) & " Sekunden."
end if


-- Zusammenstellung der Dialog-Meldung
if theDays = 0 and theHours = 0 and theMinutes = 0 and theSeconds = 0 then
set dlog to "Die Keynote beginnt JETZT!!!"
else if theDays = 0 and theHours = 0 and theMinutes = 0 then
set dlog to "Die Keynote beginnt in " & dieSekunden
else if theDays = 0 and theHours = 0 then
set dlog to "Die Keynote beginnt in " & dieMinuten & dieSekunden
else if theDays = 0 then
set dlog to "Die Keynote beginnt in " & dieStunden & dieMinuten & dieSekunden
else
set dlog to "Die Keynote beginnt in " & dieTage & dieStunden & dieMinuten & dieSekunden
end if


-- Anzeige der Dialog-Meldung
tell me
activate
display dialog ¨
dlog buttons { "Text kopieren", "Noch einmal!", "Schluß für heute!" } default button 3 giving up after 15 with icon Steve
set DialogResult to result
if button returned of the result = "Schluß für heute!" then
return
else if gave up of DialogResult then
my KeynoteTimer()
else if button returned of the result = "Text kopieren" then
tell application "Finder"
activate
set the clipboard to dlog
end tell
else
my KeynoteTimer()
end if
end tell

end KeynoteTimer

[Snow]

Hi Busyman,

um zu vermeiden, dass das eingegebene Datum beim Kompilieren ins deutsche Format umgesetzt wird, hilft folgender kleiner Umweg:

set inputDate to "21.03.2002 0:00:00"
set KeynoteDate to date inputDate

Das bringt dich einen kleinen Schritt weiter. Ich habe das allerdings gerade unter OS X getestet (Sprache umgestellt auf Englisch, Datum und Uhrzeit auf US).

Da müsste ich eingeben "03.21.2002 0:00:00"

Jetzt müsste man also die Systemversion abchecken und dann die Variable "inputDate" entsprechend anpassen.

Hier ein Beispiel für einen System-Check:

on VersionCheck() -- Check for System 9 - German Version
tell application "Finder"
--set ShortVers to version (Version des Finders)
set LongVers to product version
--if "d" is in ShortVers then set isGerman to true
if "d" is in LongVers and "9" is in LongVers then
set isGerman to true -- zum Testen auf "false" setzen
my TextSettings()
else
set isGerman to false -- set this to "true" for testing
my TextSettings()
end if
end tell
end VersionCheck

Damit habe ich mal experimentiert. - Ich müsste da allerdings jetzt selber noch weiter forschen.
_________________
Peter
-
Fischer-Bayern.de|Shadetreemicro.com

[Busyman]

Hi Snow,

hast mir mal wieder die Augen geöffnet :shocked:

Das ist ja insgesamt kniffliger, als ich dachte. Aber das Script gefällt mir so gut (wahrscheinlich, weil ich endlich einmal ein wenig Mathematik in einem Script verwende und nicht nur mit Ordnern und Dateien spiele...), daß ich die Herausforderung wohl annehmen werde :biggrin:

AppleScript ist einfach eine Gemeinheit: Hängt mal einmal drin, kommt man nicht mehr davon los.

Mit rauchendem Kopf,

Busyman

[Snow]

Habe gerade nochmal mit den Datumsformaten gespielt. Anscheinend spielt es keine Rolle, welchen Separator man benutzt. Das ist ja dann schon mal ein Vorteil. So kommt es jetzt eigentlich nur auf die Reihenfolge von Tag, Monat und Jahr an.

Von dieser Reihenfolge weichen folgende Länder ab:

Portugal - Jahr, Monat, Tag
Schweden - Jahr, Monat, Tag
USA - Monat, Tag, Jahr

Ich setze dabei mal voraus, dass Apple hier die jeweils gebräuchlichen Formate voreingestellt hat.

Jetzt bräuchten wir nur noch eine absolut sichere Methode, um die Landesversion des Systems bzw. die Ländereinstellung (OS X) zu bestimmen.
_________________
Peter
-
Fischer-Bayern.de|Shadetreemicro.com

[Busyman]

Hi Snow,

also bei einem deutschen OS, da weiß ich ja, daß stets ein "D" im Versionsnamen auftaucht. Aber wie ist das wohl bei fremdsprachigen Systemen? Steht bei den Amerikanern ein "US" im Versionsnamen? Versuche mal, mich kundig zu machen, daß wäre nämlich wirklich der einfachste Weg, die sprachabhängige Datumsformatierung einzuleiten.

Wobei mir da gerade einfällt: Wenn es möglich wäre, diesen Parameter auszulesen, dann bräuchte man auch nicht verschiedene Skripte für die einzelnen Sprachen erstellen, sondern ein Skript könnte alle Sprachen beinhalten (z.B. über  verschiedene "properties"). Wird ein spanisches System erkannt, dann wird der Enddialog auch in spanischer Sprache angezeigt. Hm, das wäre wirklich praktisch.

Eigentlich könnte man den KeynoteTimer auch gut als erstes Probe-Projekt für eine AppleScript-Studio Anwendung mißbrauchen.

Ach, schon wieder so viele Ideen, das ist herrlich :cool:

Gruß,

Busyman

[Snow]

Wobei mir da gerade einfällt: Wenn es möglich wäre, diesen Parameter auszulesen, dann bräuchte man auch nicht verschiedene Skripte für die einzelnen Sprachen erstellen, sondern ein Skript könnte alle Sprachen beinhalten (z.B. über verschiedene "properties". Wird ein spanisches System erkannt, dann wird der Enddialog auch in spanischer Sprache angezeigt. Hm, das wäre wirklich praktisch.

Genau damit habe ich schon experimentiert. Allerdings war mein Skript dafür ungeeignet. Es ist das Skript "Keychain unlock". Leider gibt es für die entsprechende Erweiterung ja auch wieder unterschiedliche Namen. "Schlüsselbund Scripting", "Keychain access"...

Deswegen habe ich es dann auch bleiben lassen. Aber das mit den Dialogen hat ganz reibungslos funktioniert.
_________________
Peter
-
Fischer-Bayern.de|Shadetreemicro.com

[Busyman]

Ist schon witzig, daß Scripter immer auf die gleichen Ideen kommen Muß daran liegen, daß jeder so wenig Code wie möglich verwenden will.

Und die Problematik Deines Scripts haben wir beim KeynoteTimer ja nicht, weil nur ein festgelegter und relativ einfacher Dialog angezeigt wird. Falls es also irgendwie möglich ist (vor allem auch unter X), die momentan verwendete Sprachversion auszulesen, dann müßte das einfach zu realisieren sein.

Nebenbei: Mir passiert es bei Deinem iCopy-Script (ein wirklich phantastischer Helfer, weil ich oft viele Icons ändern muß) öfters, daß mir aus Versehen eine Datei oder ein Ordner in den Iconspeicher rutscht. Könnte man da nicht optional eine FolderAction entwicklen, die das gar nicht zuläßt? So nach dem Motto "on adding...lege zurück das gerade hineingefallene Item...end on adding"

Nur eine Idee.

Busyman

[Snow]

[Arnt]

Hallo,
ich stand vor kurzem vor einem ähnlichen Problem. Mein erster Ansatz war, date ("3.5." & "2002") zu schreiben, das löst aber nicht das Problem bei Datumseinstellungen, die eine andere Tag-Monat Reihenfolge haben.
Was geht ist folgendes:

set TheDate to date (irgendein_Datum)
set day of TheDate to 3
set month of TheDate to May
set year of TheDate to 2002

Die Monatsnamen müssen Englisch ohne Anführungszeichen sein. Sollte auch mit z.B. US-Datumseinstelllungen klappen.

Gruß
Arnt

[Folker]

>Um eine Ordneraktion zu verwenden, müsste der Ordner geöffnet sein. Das würde aber wesentlich mehr Platz auf dem Desktop wegnehmen und außerdem könnte man das aktuell gespeicherte Icon nicht sehen.

Hallo,

dazu fällt mir ein - ich schiebe diese Ordner immer als "Schublade" an den unteren Rand des Desktops = wenig Platzverbrauch. Dabei frag ich mich, ist das Verhalten der Schubladen (ausgefahren - eingefahren) eigentlich per Script zu regeln (hallo Finder)?

Gruß,
Folker

PS: @ Arnt - das scheint mir ein Super-Tipp zu sein!

(Geändert von Folker um 9:38 Uhr am 8 Feb. 2002)
_________________
Gruß,
Folker Brandt
=============================
Systemberatung · Datenbanken · Webdesign

[Snow]

[Arnt]

[Snow]

Hi Arnt,

mit 'current date' klappt's - allerdings muss man vor der Klammer 'date' weglassen. Mit der Zeitangabe wird's dann aber etwas unbequem. Ich habe mal versucht, den Time String zu ändern mit einer Eingabe wie "18:00:00". Das führt aber zu einem 'stack overflow'.

Wenn man die Uhrzeit in Sekunden angibt geht's allerdings:

set TheDate to current date
set day of TheDate to 21
set month of TheDate to March
set year of TheDate to 2002
set time of TheDate to 64800

return TheDate
_________________
Peter
-
Fischer-Bayern.de|Shadetreemicro.com

[Snow]

[Snow]

@ Folker

Es geht! Habe mir das aber lustiger vorgestellt.

tell application "Finder"
activate
set FensterListe to every window whose popup is true
repeat with einFenster in FensterListe
set pulled open of einFenster to true
set pulled open of einFenster to false
end repeat
end tell
_________________
Peter
-
Fischer-Bayern.de|Shadetreemicro.com