Fischer-Bayern.de
 FAQFAQ   SuchenSuchen   MitgliederlisteMitgliederliste   BenutzergruppenBenutzergruppen   RegistrierenRegistrieren 
 ProfilProfil   Einloggen, um private Nachrichten zu lesenEinloggen, um private Nachrichten zu lesen   LoginLogin 

Frage an Script-Profis:

 
Neues Thema eröffnen   Neue Antwort erstellen    Fischer-Bayern.de Foren-Übersicht -> AppleScript X
Vorheriges Thema anzeigen :: Nächstes Thema anzeigen  
Autor Nachricht
Maczeug
•->
•->


Anmeldedatum: 24.03.2003
Beiträge: 2

BeitragVerfasst am: 24.03.2003 - 22:47    Titel: Frage an Script-Profis: Antworten mit Zitat

Kann mir jemand ein Script basteln, das mir vor einen Dateinamen auf Wunsch das Erstellungsdatum im Format JJJJ-MM-TT stellt, also z.B. "2003-03-23 Datei.pdf"????

Freu mich über Eure Ideen!!!

Thomas

Bin leider gar kein Script Fachmann, nutze einfach nur gerne die Scripts.....
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden AIM-Name
Snow
Administrator
Administrator


Anmeldedatum: 21.11.2000
Beiträge: 1955
Wohnort: Deiningen

BeitragVerfasst am: 25.03.2003 - 00:05    Titel: Antworten mit Zitat

Hallo Thomas,

hier mal ein Schnellschuss:

on run
 set dieDatei to choose file with prompt "Bitte eine Datei auswählen"
 doTheTrick(dieDatei)
end run

on open DateiListe
 repeat with dieDatei in DateiListe
  doTheTrick(dieDatei)
 end repeat
end open

on doTheTrick(dieDatei)
 tell application "Finder"
  set creationDate to creation date of dieDatei
 end tell
 
 set derTag to text -2 thru -1 of ( "0" & creationDate's day)
 set MonatsListe to { January, February, March, April, May, June, July, ¬
  August, September, October, November, December }
 repeat with i from 1 to 12
  if creationDate's month = item i of MonatsListe then
   set Monat to text -2 thru -1 of ( "0" & i)
   exit repeat
  end if
 end repeat
 set Jahr to ((year of creationDate) as text)
 set Datum_kurz to Jahr & "-" & Monat & "-" & derTag & " "
 tell application "Finder"
  set alterName to name of dieDatei
  set neuerName to Datum_kurz & alterName
  set name of dieDatei to neuerName
 end tell
end doTheTrick


Sichere das Skript als Programm, dann kannst du es auch als Droplet benutzen (also einfach Dateien drauf ziehen).

Was das ganze Zeug soll, erfährst du in den beiden Workshop-Artikeln Datum formatieren 1 + 2.

Was im Skript noch fehlt, wäre eine Überprüfung der Länge des Dateinamens. Vielleicht kommst du ja auf den Geschmack und tüftelst das selbst aus. Wink

Gruß
_________________
Peter
-
Fischer-Bayern.de|Shadetreemicro.com
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden Website dieses Benutzers besuchen AIM-Name
Maczeug
•->
•->


Anmeldedatum: 24.03.2003
Beiträge: 2

BeitragVerfasst am: 25.03.2003 - 18:27    Titel: Vielen, vielen, Antworten mit Zitat

vielen Dank!!!!!

Das war das, was ich gebraucht habe!!!!
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden AIM-Name
Beiträge der letzten Zeit anzeigen:   
Neues Thema eröffnen   Neue Antwort erstellen    Fischer-Bayern.de Foren-Übersicht -> AppleScript X Alle Zeiten sind GMT + 2 Stunden
Seite 1 von 1

 
Gehe zu:  
Du kannst keine Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum nicht antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.


Powered by phpBB © 2001, 2002 phpBB Group
Deutsche Übersetzung von phpBB.de


AppleScript für absolute Starter