Differenz zwischen Datumsangaben ausrechnen? - Zeit bis zur

[Busyman]

Hallo liebes Forum!

Habe mir die Informationen, die Apple zum Rechnen mit Datumsangaben bereitstellt, schon zu Gemüte geführt, bin aber nicht sehr viel schlauer geworden. Mein Problem: Ich würde gerne ein Script für die Startobjekte haben, das mir immer die Zeit bis z.B. der nächsten Keynote oder anderen wichtigen Terminen anzeigt. Geht das mit AppleScript?

Freue mich auf Eure erh*ll
enden Beiträge,

Busyman

(Geändert von Busyman am 19:04 Uhr am 22 Dez. 2001)

[Snow]

Hi Busyman,

hier ein kleines Skript aus meiner Sammlung. Das kannst du entsprechend anpassen. Wichtig bei der Sache ist, dass Applescript Zeitdifferenzen in Sekunden berechnet. Das sollte man nicht vergessen.

set date1 to date (text returned of ¨
(display dialog "Geben Sie ein Datum im Format TT.MM.JJJJ ein." buttons ¨
{ "OK" } default button 1 default answer "" ))
set date2 to current date

set ZeitDifferenz to (date1 - date2)
set TagesDifferenz to round (ZeitDifferenz / 86400) rounding as taught in school
display dialog "Zwischen dem eingegebenen Datum und heute liegen " & ¨
TagesDifferenz & " Tage." buttons { "Danke" } default button 1 with icon note

Den Eingabedialog kannst du natürlich durch ein, im Skript festgelegtes Datum ersetzen. Aber dir wird schon was einfallen.

Das eingegebene Datum darf auch ruhig die Uhrzeit beinhalten. Auch wenn ich im Dialog das Format TT.MM.JJJJ verlange. AppleScript ist bei der Umsetzung eines Strings in ein Datumformat ziemlich flexibel und verkraftet eine ganze Menge.

Im Skript habe ich mal ganz großzügig auf Tage gerundet. Das Ergebnis kannst du natürlich durchaus verfeinern. Wenn du den Unterschied zwischen zwei Daten berechnest ist das Ergebnis immer sekundengenau. 'current date' beinhaltet die sekundengenaue Uhrzeit. Wenn im eingegebenen Datum keine Uhrzeit angegeben wird, wird automatisch 00:00:00 Uhr zur Berechnung verwendet.
_________________
Peter
-
Fischer-Bayern.de|Shadetreemicro.com

[Busyman]

Hallo Snow,

es wird ja langsam (aber immer glücklicherweise) zur Regel:

Vielen Dank für den Lösungsansatz, ich bin durch Dein Script und Deine Ausführungen zur endgültigen Lösung gekommen, habe zudem die Operatoren "mod" und "div" kennengelernt. Das kann man doch mal einen Erfolg nennen

Hier der Scriptcode:

on run
my KeynoteTimer()
end run

on KeynoteTimer()
set keynoteDate to date "Montag, 7. Januar 2002 18:00:00 Uhr" --kalifornische Zeit umgerechnet in deutsche Ortszeit
set actualDate to current date

set timeDif to (keynoteDate - actualDate)

set theDays to (timeDif div 86400)

set secondsLeftA to (timeDif mod 86400)

set theHours to (secondsLeftA div 3600)

set secondsLeftB to (secondsLeftA mod 3600)

set theMinutes to (secondsLeftB div 60)

set theSeconds to (secondsLeftB mod 60)

tell application "Finder"
activate
display dialog ¨
"Die Keynote beginnt in " & theDays & " Tagen, " & theHours & " Stunden, " & theMinutes & " Minuten und " & theSeconds & " Sekunden." buttons { "Noch einmal!", "Schluß für heute!" } default button 2
set DialogResult to result
if button returned of the result = "Schluß für heute!" then
return
else
my KeynoteTimer()
end if
end tell
end KeynoteTimer


Und hier gibt es das fertige Script:
http://www.ame-electroplating.com/busyman/applescripts/BusymansKeynoteTimer.sit

Also, nochmals einen Dank an Dich und lieben Gruß,

Busyman