Fischer-Bayern.de
 FAQFAQ   SuchenSuchen   MitgliederlisteMitgliederliste   BenutzergruppenBenutzergruppen   RegistrierenRegistrieren 
 ProfilProfil   Einloggen, um private Nachrichten zu lesenEinloggen, um private Nachrichten zu lesen   LoginLogin 

Script gesucht: PDFs einordnen per Tastenanschlag

 
Neues Thema eröffnen   Neue Antwort erstellen    Fischer-Bayern.de Foren-Übersicht -> AppleScript X
Vorheriges Thema anzeigen :: Nächstes Thema anzeigen  
Autor Nachricht
rumbleinthedesert
•->
•->


Anmeldedatum: 08.02.2010
Beiträge: 12

BeitragVerfasst am: 16.03.2010 - 23:34    Titel: Script gesucht: PDFs einordnen per Tastenanschlag Antworten mit Zitat

Hallo Forum

Ich suche ein Script oder Lösungsvorschläge mit folgender Eigenschaft:

Ich habe einen Ordner mit vielen PDF-Dateien, diese sollen je nach Inhalt des PDFs (Familienname) Hierarchisch nach dem Alphabet sortiert werden.
Also in einen Ordner A, einen Ordner B, einen Ordner C u.s.w..

Jetzt wäre es natürlich toll, wenn ich die erste Datei öffne, diese dann, wenn sie z.B. in den Ordner B soll, mit dem Tastenanschlag B in den Ordner B verschieben kann.

Anschliessend wird automatisch die nächste Datei geöffnet, wenn diese z.B. in den Ordner A soll, wird sie mit dem Tastenanschlag A in den Ordner A verschoben u.s.w.

Danke im Voraus für eure Antworten.

lg

r
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden
hubionmac
•--->
•--->


Anmeldedatum: 26.02.2004
Beiträge: 245
Wohnort: Münster

BeitragVerfasst am: 17.03.2010 - 02:08    Titel: Antworten mit Zitat

Steht in den PDF vielleicht etwas indizierbares drin, dann könntest Du Dir das Öffnen sparen und die Arbeit das Skript+Spotlight machen lassen...
_________________
hubionmac.com akzeptiere Paypal und Pizza
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden Website dieses Benutzers besuchen
rumbleinthedesert
•->
•->


Anmeldedatum: 08.02.2010
Beiträge: 12

BeitragVerfasst am: 17.03.2010 - 08:59    Titel: Antworten mit Zitat

hubionmac hat Folgendes geschrieben:
Steht in den PDF vielleicht etwas indizierbares drin, dann könntest Du Dir das Öffnen sparen und die Arbeit das Skript+Spotlight machen lassen...


Nein, leider nicht, es sind von Hand geschriebene Zettel, mit Namen drauf ,welche eingescannt wurden ...

Ich arbeite sonst mit PDFs immer mit DevonThink. Da könnte ich die Datei anwählen und hätte direkt auch eine Grossansicht des Inhalts. Aber in deren Forum konnte mir auf die gleiche Frage niemand weiterhelfen.

Wieder mal danke für Deine schnelle Antwort Hubi!

Deine Website finde ich cool! Habe gestern wieder TotalFinder installiert, der wird langsam wirklich gut.
Pathfinder ist mir viel zu aufgeblasen und träge.

lg

r
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden
hubionmac
•--->
•--->


Anmeldedatum: 26.02.2004
Beiträge: 245
Wohnort: Münster

BeitragVerfasst am: 17.03.2010 - 10:38    Titel: Antworten mit Zitat

Hach, soviel Lob und dann noch so unerwartet Embarassed

Was Dein Problem angeht, hier etwas Code, den Du am besten als Programm abspeicherst....
Du ziehst dann den Ordner mit den PDFs auf das Skript-Programm (in dem Ordner sollten dann auch schon die Ordner A,B,C oder sonst wie angelegt sein) also:


Was nun passiert: Das Skript baut sich eine Liste aller Ordnernamen in thefolder und öffnet der Reihe nach alle PDFs in dem Ordner thefolder und zeigt Dir dazu eine Auswahlliste, dann nur noch die Anfangsbuchstaben der Ordnernamen drücken, enter, PDF wird geschlossen, verschoben, nächstes....

Zitat:
on open thefolder
   if (count of thefolder) = 1 then
      tell application "Finder"
         set thefolder to (item 1 of thefolder) as alias
         set thefolder_posix to POSIX path of (thefolder as alias)
         set sort_destis to name of every folder of thefolder
         set thepdfs to every file of thefolder
         
         repeat with thepdf in thepdfs
            if name of thepdf ends with ".pdf" then
               set thepdf_posix to POSIX path of (thepdf as alias)
               do shell script "open -a /Applications/Preview.app " & quoted form of thepdf_posix
               tell me to activate
               tell me to set thedesti to choose from list sort_destis with prompt "In welchen Ordner verschieben?"
               
               tell application "Preview"
                  activate
                  
                  --kleiner Pfusch, weil die Vorschau keine AppleScript-Befehle kennt...
                  tell application "System Events"
                     keystroke "w" using command down
                  end tell
               end tell
               do shell script "mv " & quoted form of thepdf_posix & " '" & thefolder_posix & thedesti & "/" & my checkname_with_pdf_suffix(name of thepdf, ((thefolder & thedesti) as text) as alias, false) & "'"
            end if
         end repeat
      end tell
      
      tell me to activte
      tell me to display dialog "bin am Ende"
   end if
end open

on checkname_with_pdf_suffix(n, D, looped)
   tell application "Finder"
      set thefiles to name of every item of (D as alias)
   end tell
   if thefiles contains n then
      if looped = false then
         set n to ((characters 1 through -5 of n) & " 1" & (characters -4 through -1 of n)) as text
         my checkname_with_pdf_suffix(n, D, true)
      else
         set tmp to (last word of ((characters 1 through -5 of n) as text) as integer)
         set tmpcount to (count of characters of (tmp as text)) + 5
         set tmp to tmp + 1
         set n to ((characters 1 through (-1 * tmpcount) of n) & tmp & (characters -4 through -1 of n)) as text
         my checkname_with_pdf_suffix(n, D, true)
      end if
   else
      return n
   end if
end checkname_with_pdf_suffix

_________________
hubionmac.com akzeptiere Paypal und Pizza
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden Website dieses Benutzers besuchen
rumbleinthedesert
•->
•->


Anmeldedatum: 08.02.2010
Beiträge: 12

BeitragVerfasst am: 17.03.2010 - 21:27    Titel: thanks a bunch! Antworten mit Zitat

Hey Hubi, vielen vielen Dank für das super Script.

Es ging eine kleine Spende auf Deiner wunderbaren Homepage ein!

Das Script funktioniert super! Bis auf die Zeile:

Code:

      tell me to activte
      tell me to display dialog "bin am Ende"


wo bei activate richtig ist.

Ich danke Dir auf Knien Smile

lg.

r
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden
hubionmac
•--->
•--->


Anmeldedatum: 26.02.2004
Beiträge: 245
Wohnort: Münster

BeitragVerfasst am: 17.03.2010 - 21:28    Titel: Antworten mit Zitat

Ich sage auch Merci vielmals Exclamation
_________________
hubionmac.com akzeptiere Paypal und Pizza
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden Website dieses Benutzers besuchen
Beiträge der letzten Zeit anzeigen:   
Neues Thema eröffnen   Neue Antwort erstellen    Fischer-Bayern.de Foren-Übersicht -> AppleScript X Alle Zeiten sind GMT + 2 Stunden
Seite 1 von 1

 
Gehe zu:  
Du kannst keine Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum nicht antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.


Powered by phpBB © 2001, 2002 phpBB Group
Deutsche Übersetzung von phpBB.de


AppleScript für absolute Starter