Fischer-Bayern.de
 FAQFAQ   SuchenSuchen   MitgliederlisteMitgliederliste   BenutzergruppenBenutzergruppen   RegistrierenRegistrieren 
 ProfilProfil   Einloggen, um private Nachrichten zu lesenEinloggen, um private Nachrichten zu lesen   LoginLogin 

ausgewählte Dateien automatisch in Ordner verschieben

 
Neues Thema eröffnen   Neue Antwort erstellen    Fischer-Bayern.de Foren-Übersicht -> AppleScript X
Vorheriges Thema anzeigen :: Nächstes Thema anzeigen  
Autor Nachricht
Hansfox
•->
•->


Anmeldedatum: 17.06.2009
Beiträge: 2
Wohnort: Hamburg

BeitragVerfasst am: 17.06.2009 - 15:44    Titel: ausgewählte Dateien automatisch in Ordner verschieben Antworten mit Zitat

Hallo zusammen,

ich bin ein absoluter Anfänger in Sachen Apple Script und habe eine Frage an die Community:

Aus Programmen wie Photoshop oder Cinema 4D kennt man die Funktion, ausgewählte Ebenen oder Objekte mit einem Kurzbefehl automatisch zu gruppieren. Die entsprechenden Ebenen oder Objekte liegen dann in einem Überordner. Eine solche Funktion wäre für mich im Finder auch absolut hilfreich, da ich häufig viele Daten z.B. auf dem Schreibtisch liegen habe, die thematisch zusammengehören und die ich anschließend alle von Hand wegsortieren muss. Besser wäre es, ein Script legte mir automatische einen neuen Ordner (Eingabedialog zur Benennung des Ordners wäre auch toll) an, in dem alle Files landen.

Idealerweise sollte die Funktion auch über einen Kurzbefehl aufgerufen werden können. Ist so etwas möglich?


Vielen Dank und Gruß!
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden
Wolle-77
•--->
•--->


Anmeldedatum: 25.02.2003
Beiträge: 449
Wohnort: Geldern

BeitragVerfasst am: 17.06.2009 - 23:08    Titel: Antworten mit Zitat

Hallo Hansfox,

das ist eigentlich eine interessante Idee. Ich mache mich mal ans Werk und versuche das, möglichst effizient und optimiert arbeitend zu entwickeln...

Bis später...
_________________
Martin Wolter
--
Apple rocks the planet!
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden
Wolle-77
•--->
•--->


Anmeldedatum: 25.02.2003
Beiträge: 449
Wohnort: Geldern

BeitragVerfasst am: 17.06.2009 - 23:44    Titel: Antworten mit Zitat

So, fertig:

Das folgende Script als Programm-Bundle unter dem Namen "Ausgewählte Objekte verschieben" abspeichern und am Besten ins Dock packen. So ist es sehr schnell mit nur einem Klick aufgerufen, was einem Kurzbefehl in nichts nachsteht:

Code:
tell application "Finder"
   set dateien to get selection
   if dateien is not {} then
      set ort to container of (first item of dateien)
      set ordnername to (display dialog "Welchen Namen soll der Ordner mit den ausgewählten Objekten erhalten?" default answer (my vorschlag()) buttons {"Abbruch, Objekte belassen", "Ok"} default button 2 giving up after 60)
      if button returned of ordnername is not "Abbruch, Objekte belassen" then
         set ordnername to text returned of ordnername
         try
            set ordner to make new folder at ort with properties {name:ordnername}
         on error
            beep
            set ordnername to my vorschlag()
            set ordner to make new folder at ort with properties {name:ordnername}
         end try
         try
            move dateien to ordner without replacing
         on error
            beep 2
            display dialog "Die Objekte konnten nicht verschoben werden. Stellen Sie sicher, daß Sie die Rechte dazu haben. Versuchen Sie es mit anderen Dateien erneut…" buttons {"Ok"} default button 1 giving up after 10
         end try
      end if
   end if
end tell

on vorschlag()
   return ("Ordner_" & my dindatum()) as string
end vorschlag

on dindatum()
   set t to (current date)
   set monat to text -2 thru -1 of ("0" & ((month of t) as integer))
   set mtag to text -2 thru -1 of ("0" & (day of t))
   set stunde to text -2 thru -1 of ("0" & (hours of t))
   set minute to text -2 thru -1 of ("0" & (minutes of t))
   set sekunde to text -2 thru -1 of ("0" & (seconds of t))
   return (year of t & monat & mtag & "-" & stunde & minute & sekunde) as string
end dindatum


Bitte schön...

Kurz zur Erklärung: Im Kern ist es doch viel weniger, als ich gedacht habe; daher habe ich direkt ein wenig Luxus und genügend "Benutzerschutz" hinzugepackt, der dann doch etwas mehr Code wurde. Aber schau es Dir an, es ist sehr kurz vom Ablauf und ich denke, leicht zu verstehen.
_________________
Martin Wolter
--
Apple rocks the planet!
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden
Hansfox
•->
•->


Anmeldedatum: 17.06.2009
Beiträge: 2
Wohnort: Hamburg

BeitragVerfasst am: 18.06.2009 - 10:59    Titel: Besten Dank! Antworten mit Zitat

Ahhh, super!

Vielen Dank Martin, das funktioniert ja einwandfrei. Das Problem des nicht vorhandenen Kurzbefehls habe ich über den Maustreiber gelöst, sprich: beim Drücken einer Sondertaste wird das Script aufgerufen.
Das erleichtert mir vieles und ich bin froh, mich an Dich/Euch gewendet zu haben.


Merci,

Hansfox
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden
Skeeve
•---->
•---->


Anmeldedatum: 20.04.2006
Beiträge: 1068

BeitragVerfasst am: 18.07.2009 - 07:59    Titel: Antworten mit Zitat

Ich hatte vor einiger Zeit auch mal sowas erstellt, bisher aber nie in Freiheit entlassen. Vielleicht gefällt's ja jemandem: http://skeeve42.blogspot.com/2009/07/new-folder-from-selection.html
_________________
"All problems are solved in slightly less than half an hour" (Chumbawamba, "Hey Hey We're The Junkies")
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden
dogsch
•-->
•-->


Anmeldedatum: 19.12.2000
Beiträge: 85

BeitragVerfasst am: 20.07.2009 - 15:13    Titel: Antworten mit Zitat

tolles Teil - vielen Dank!

wenn man jetzt aber eine Datei ohne vorherige Auswahl per Pfadangabe verschieben will scheint es nicht zu funktionieren.

Oder was muß als Pfad angegeben werden?
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden Website dieses Benutzers besuchen
Skeeve
•---->
•---->


Anmeldedatum: 20.04.2006
Beiträge: 1068

BeitragVerfasst am: 20.07.2009 - 21:52    Titel: Antworten mit Zitat

dogsch hat Folgendes geschrieben:
wenn man jetzt aber eine Datei ohne vorherige Auswahl per Pfadangabe verschieben will scheint es nicht zu funktionieren.

Falls Du mein script meinst: Das ist dafür programmiert auf einer Auswahl zu arbeiten. Ich sehe keinen Sinn darin, einen Pfad von Hand einzugeben. Aber vielleicht hast Du ja ein Anwendungsbeispiel, damit sich mir der Sinn erschließt?
_________________
"All problems are solved in slightly less than half an hour" (Chumbawamba, "Hey Hey We're The Junkies")
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden
dogsch
•-->
•-->


Anmeldedatum: 19.12.2000
Beiträge: 85

BeitragVerfasst am: 21.07.2009 - 10:04    Titel: Antworten mit Zitat

Skeeve hat Folgendes geschrieben:
Falls Du mein script meinst: Das ist dafür programmiert auf einer Auswahl zu arbeiten. Ich sehe keinen Sinn darin, einen Pfad von Hand einzugeben. Aber vielleicht hast Du ja ein Anwendungsbeispiel, damit sich mir der Sinn erschließt?


hatte ich vor ewigen Zeiten schonmal im AS Classic Forum gepostet:

>habe eine FileMaker Datenbank mit ca. 1000 Artikeln, welches jedes >einzelne ein Bild hat.
>Jetzt habe ich eine neue Datenbank mit zum Teil identischen Artikeln.
>Was ich jetzt machen will ist, dass ich einen Button in der Datensatzmaske
>der neuen Datenbank habe womit ich das Bild importieren kann (erledigt FM)
>und gleichzeitig das Bild der alten Datenbank in das Verzeichnis der neuen
>kopiert wird.
>Ich hoffe ich habe es verständlich ausgedrückt

Im Moment mache ich es so und ich dachte, mit der Pfasangabe wäre es eleganter:

Code:
tell current record
set datei to cell "Bildname"
set dateikopie to cell "Bildname_Kopie"
set dateineu to cell "Bildname_neu"
display dialog datei & " - " & dateikopie
end tell

tell application "Finder"
try
duplicate file datei of folder "Bilder" of folder "FM Test ƒ" of folder "Desktop" of folder "dirkschiemann" of folder "Users" of startup disk
set name of document file dateikopie of folder "Bilder" of folder "FM Test ƒ" of folder "Desktop" of folder "dirkschiemann" of folder "Users" of startup disk to dateineu
on error
beep 2
display dialog "Die Objekte konnten nicht verschoben werden. Stellen Sie sicher, daß Sie die Rechte dazu haben. Versuchen Sie es mit anderen Dateien erneut…" buttons {"Ok"} default button 1 giving up after 10
end try
end tell
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden Website dieses Benutzers besuchen
Skeeve
•---->
•---->


Anmeldedatum: 20.04.2006
Beiträge: 1068

BeitragVerfasst am: 22.07.2009 - 20:23    Titel: Antworten mit Zitat

Wenn Du wirklich alle diese Bilder rüberholen willst, dann mach das lieber mit einem kleinen Shellscript statt mit Buttonklick.

Exportiere Dir alle Dateinamen und lass eine kleine Shell Schleife drüber laufen. Soll ich helfen?
_________________
"All problems are solved in slightly less than half an hour" (Chumbawamba, "Hey Hey We're The Junkies")
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden
dogsch
•-->
•-->


Anmeldedatum: 19.12.2000
Beiträge: 85

BeitragVerfasst am: 23.07.2009 - 12:39    Titel: Antworten mit Zitat

nee danke, ich mach das so wie ich geschrieben habe - klappt ganz gut, nur wollte ich es in "hübsch"
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden Website dieses Benutzers besuchen
Beiträge der letzten Zeit anzeigen:   
Neues Thema eröffnen   Neue Antwort erstellen    Fischer-Bayern.de Foren-Übersicht -> AppleScript X Alle Zeiten sind GMT + 2 Stunden
Seite 1 von 1

 
Gehe zu:  
Du kannst keine Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum nicht antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.


Powered by phpBB © 2001, 2002 phpBB Group
Deutsche Übersetzung von phpBB.de


AppleScript für absolute Starter