Fischer-Bayern.de
 FAQFAQ   SuchenSuchen   MitgliederlisteMitgliederliste   BenutzergruppenBenutzergruppen   RegistrierenRegistrieren 
 ProfilProfil   Einloggen, um private Nachrichten zu lesenEinloggen, um private Nachrichten zu lesen   LoginLogin 

appMaker

 
Neues Thema eröffnen   Neue Antwort erstellen    Fischer-Bayern.de Foren-Übersicht -> Pool
Vorheriges Thema anzeigen :: Nächstes Thema anzeigen  
Autor Nachricht
Skeeve
•---->
•---->


Anmeldedatum: 20.04.2006
Beiträge: 1068

BeitragVerfasst am: 02.06.2008 - 10:15    Titel: appMaker Antworten mit Zitat

Kleines Hleferlein um aus einem Script/Shellexecutable, das kein Terminalfenster benötigt, eine .app zu erstellen.
Code:
 --
-- appMaker © 2008 by Skeeve
-- appMaker.question.Skeeve at xoxy dot net
--
-- Drag & Drop eines Shell-Scripts
-- oder "shell executables" auf appMaker
-- erzeugt ein doppelklickbares Programm-Bundle
-- auf dem Desktop
--
-- ToDo:
-- Droplet erstellen.
-- 
property target : "~/Desktop"
property directory : "MyScript"

on run
   tell me to open {choose file}
end run

on open an_item
   -- Nur eine Datei?
   if (count of an_item) ≠ 1 then
      display alert "Nur eine Datei bitte!" as critical
      error -128
   end if
   set an_item to first item of an_item
   -- Informationen holen?
   set information to info for an_item
   -- Verzeichnisse sind unzulässig
   if folder of information then
      display alert "Bitte keine Verzeichnisse!" as critical
      error -128
   end if
   -- Ausführbar muß die Datei auch sein
   try
      do shell script "test -x " & quoted form of POSIX path of an_item
   on error
      display alert "»" & (POSIX path of an_item) & "« ist keine ausführbare Datei" as critical
      error -128
   end try
   set appname to name of information
   -- Extension vorhanden?
   if name extension of information is not missing value then
      -- Aber bitte nicht .app!
      if name extension of information is "app" then
         display alert "app ist keine unterstützte extension" as critical
         error -128
         
      end if
      -- Extension abschneiden
      set l to length of name extension of information
      set appname to text 1 thru (-2 - l) of appname
   end if
   -- appname vervollständigen
   set appname to target & "/" & (quoted form of appname) & ".app"
   -- Zielverzeichnis vervollständigen
   set dir to appname & "/Contents/Resources/" & quoted form of directory
   -- Los geht's
   -- 1. Compilieren
   -- 2. Verzeichnis anlegen
   -- 3. Kopieren
   do shell script "osacompile -o " & appname & " -e " & quoted form of ("
      on run
         do shell script quoted form of ((posix path of (path to resource \"" & directory & "\")) & (\"" & name of information & "\"))
      end") & ";
      mkdir " & dir & ";
      cp " & (quoted form of POSIX path of an_item) & " " & dir
end open

_________________
"All problems are solved in slightly less than half an hour" (Chumbawamba, "Hey Hey We're The Junkies")
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden
Beiträge der letzten Zeit anzeigen:   
Neues Thema eröffnen   Neue Antwort erstellen    Fischer-Bayern.de Foren-Übersicht -> Pool Alle Zeiten sind GMT + 2 Stunden
Seite 1 von 1

 
Gehe zu:  
Du kannst keine Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum nicht antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.


Powered by phpBB © 2001, 2002 phpBB Group
Deutsche Übersetzung von phpBB.de


AppleScript für absolute Starter