Systemeinstellung/Energie sparen/Prozessorleistung

[giesskanne]

Hallo,

kann mir jemand sagen, wie ich die Systemeinstellung "Energie sparen" anspreche, um die Prozessorleistung auf minimal zu setzen, bzw. switchen von automatisch auf minimal und umgekehrt?

Dank im Voraus.

[spirigwi]

[Snow]

Mit dem UI Elements Inspector lässt sich leicht die Objekthierarchie herausfinden.

Eine Überprüfung damit ist auch dringend anzuraten, da GUI Scripting eine recht unzuverlässige Sache sein kann. Oft ändert sich eine Kleinigkeit von einer Systemversion zur nächsten, und schon klappt das Skript nicht mehr.

Auf meinem Rechner läuft's derzeit so:

tell application "System Preferences"
    activate
    set current pane to pane "com.apple.preference.energysaver"
end tell
tell application "System Events"
    tell process "System Preferences"
        tell window 1
            
            if (exists tab group 1) then
                tell tab group 1
                    click radio button 2
                    delay 1
                    tell pop up button 1
                        set x to value
                        if x is not "Minimal" then
                            click
                            delay 1
                            tell menu 1
                                click menu item "Minimal"
                            end tell
                        else
                            click
                            delay 1
                            tell menu 1
                                click menu item "Automatisch"
                            end tell
                        end if
                    end tell
                end tell
            end if
        end tell
        delay 1
        keystroke "w" using command down
    end tell
end tell

@ Willy
Wolltest du uns mit deinem Beitrag irgendetwas mitteilen?
_________________
Peter
-
Fischer-Bayern.de|Shadetreemicro.com

[spirigwi]

Ja, ich hatte auch über direkte Pfade probiert, dann kam ich aber in Verwzeiflung wil nur gewisse ansprechbar waren, gerade ein Häufchen Elend hat funktioniert:
--man kann mit glück auch die Pfade öffnen, der "Energy Saver" ist wieder mal nicht dabei
set ButtNameList to {button1:"Appearance", button2:"Dashboard & Exposé", button3:"System Preferences", button4:"Dock", button5:"International", button6:"Security", button7:"Spotlight", button8:"System Preferences", button9:"AL1511", button10:"Energy Saver", button11:"System Preferences", button12:"System Preferences", button13:"System Preferences", button14:"System Preferences", button15:"Network", button16:"system prefs", button17:"Sharing", button18:"System Preferences", button19:"universalaccess", button20:"Date & Time"}
tell application "System Preferences"
activate
set PanePfad to "com.apple.preference." & button15 of ButtNameList
set current pane to pane PanePfad
(* --es gehen:
button19
button15
button6
button4
*)
end tell
Erst durch deine Hilfe sieht man dass die Namen so unterschiedlich sind:
einmal "energysaver" ein andermal "energy saver". Wie man diese Namen herausfindet, an dem Punkt habe ich dann die Nerven verloren. Meine Mitteilung also ein Hilferuf:
könntest du nicht einen Trick zeigen wie man diese Namen lesen lassen kann von System Events oder irgend etwas.
Ps:
Dein Skript funktioniert aber tadellos, danke Snow, nichts für ungut

EDIT(darf sicher noch anfügen weil nichts zu tun mit giesskannes Antwort:)

[giesskanne]

Hallo Snow und spirigwi,

oh, daß es so kompliziert ist, hätte ich nicht erwartet.
Das PullDown-Menü ist nicht als Objekt des Engery Saver-Objekts anzusprechen, sondern nur über die UI?

Aber Dein Skript, Snow, funktioniert tadellos.
Herzlichen Dank.

Ich brauch das, um meine Prozessoren, die sich in letzter Zeit öfters überhitzen, was zu einen sudden shutdown führt, einen Gang runterzuschalten. Da nervt es, wenn an sich jedes Mal über die Systemeinstellung zu dem zweiten Reiter von "Energie sparen" durchhangeln muß, um mit der Maus das DropDown zu öffnen und die Zielleistung auszuwählen.

Herzlichen Dank für diese Erleichterung, auch wenn der Weg dorhin so dornenreich ist.