Fischer-Bayern.de
 FAQFAQ   SuchenSuchen   MitgliederlisteMitgliederliste   BenutzergruppenBenutzergruppen   RegistrierenRegistrieren 
 ProfilProfil   Einloggen, um private Nachrichten zu lesenEinloggen, um private Nachrichten zu lesen   LoginLogin 

iPhoto-Import

 
Neues Thema eröffnen   Neue Antwort erstellen    Fischer-Bayern.de Foren-Übersicht -> Pool
Vorheriges Thema anzeigen :: Nächstes Thema anzeigen  
Autor Nachricht
DickerZeh
•-->
•-->


Anmeldedatum: 28.12.2001
Beiträge: 23

BeitragVerfasst am: 11.02.2006 - 00:22    Titel: iPhoto-Import Antworten mit Zitat

Was macht das Skript?
Als Ordneraktion angehängt, werden alle dort abgelegten Bilder in iPhoto importiert. Dann werden sie in Unterordner des User-Bilderordners eingruppiert, für jeden Monat (ermittelt nach dem Erstellungsdatum des ersten importierten Bildes) ein Ordner nach dem Muster "2006_02".
(Hierfür muss ein Temp-Ordner angelegt werden, weil der import-Befehl von iPhoto schlecht dokumentiert ist und offensichtlich nur komplette Ordner einliest)

Voraussetzungen:
Erstellt wurde das Skript unter Mac OS X.4.4 und iPhoto6.
Vor allem mit iPhoto6 ergibt das Script erst Sinn, weil nicht mehr wie früher beim Import Kopien innerhalb der iPhoto Library erstellt werden, sondern nur noch Alias-Dateien.

Viel Spaß und Erfolg mit dem Skript.
Smile Dirk

Code:
global MyMonth
global MyMonthNumber

on adding folder items to thisFolder after receiving TheseItems
   set Bilderordner to (path to pictures folder as string)
   
   tell application "Finder"
      try
         --Erstellungsdatum für Ordnernamen ermitteln
         set mydate to the creation date of the first item in TheseItems as string
         set myyear to word 4 of mydate
         set MyMonth to word 3 of mydate
         my MonatsZahl()
         
         --neuen Ordner erstellen
         set NeuerOrdner to myyear & "_" & MyMonthNumber
         set NeuerOrdnerPfad to Bilderordner & NeuerOrdner & ":"
         if not (exists NeuerOrdnerPfad) then
            make new folder at folder Bilderordner
            set the name of the result to NeuerOrdner
         end if
         
         --Tempordner für Dateiimport erstellen
         set TempOrdner to Bilderordner & "Import:"
         if not (exists TempOrdner) then
            make new folder at folder Bilderordner
            set the name of the result to "Import"
         end if
         move (every file of folder thisFolder) to (TempOrdner)
         
         --Bilder importieren
         tell application "iPhoto"
            activate
            import from alias TempOrdner without force copy
            repeat while importing
            end repeat
         end tell
         
         --Bilder in richtigen Dateiordner verschieben
         move (every file of folder TempOrdner) to (NeuerOrdnerPfad)
         --Tempordner wieder löschen
         delete TempOrdner
         
      on error errMsg
         display dialog errMsg
      end try
   end tell
end adding folder items to


--Daten für den Namen des Bilderordner ermitteln
on MonatsZahl()
   set MonatsListe to {"Januar", "Februar", "März", "April", "Mai", "Juni", "Juli", "August", "September", "Oktober", "November", "Dezember"}
   repeat with i from 1 to 12
      if MyMonth = item i of MonatsListe then
         set MyMonthNumber to text -2 thru -1 of ("0" & i)
         exit repeat
      end if
   end repeat
end MonatsZahl
[/code]
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden
Beiträge der letzten Zeit anzeigen:   
Neues Thema eröffnen   Neue Antwort erstellen    Fischer-Bayern.de Foren-Übersicht -> Pool Alle Zeiten sind GMT + 2 Stunden
Seite 1 von 1

 
Gehe zu:  
Du kannst keine Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum nicht antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.


Powered by phpBB © 2001, 2002 phpBB Group
Deutsche Übersetzung von phpBB.de


AppleScript für absolute Starter