Ordner mit Droplet bearbeiten! - aber wie geht das?

[sideshow]

Morgen Forum,

ich hab ein kleines Problem. Ich möchte die Namen von Dateien in einem Ordner ändern. Den Ordner zieht man vorher auf ein Droplet. Das Droplet steht soweit, aber wenn ich den Ordner darauf schiebe, wird nur der Name des ORDNERS, nicht aber der Name der Dateien (des Ordners) bearbeitet.

Wie stelle ich das denn nun richtig an? Dankbar für jede Hilfe.

Noch einen angenehmen Arbeitstag. Grüße, sideshow
_________________
Meine Wenigkeit im Internet: http://www.sideshow-systems.de

[Folker]

Moin sideshow,

was es braucht ist Rekursion - aber ehe ich jetzt anfange das darzustellen - Apple kann es besser!
http://www.apple.com/applescript/help_mods.html
Dort findest Du die "AppleScript Guidebooks". "Essential Sub-routines" sind in Deinem Fall die richtigen (gibt es neuerdings sogar als X-Version!). Wenn Du das installiert hast sehe Dir die "Finder-Droplets" an. Besser kann es nicht erklärt werden.

Gruß,
Folker
_________________
Gruß,
Folker Brandt
=============================
Systemberatung · Datenbanken · Webdesign

[sideshow]

Hi Folker,

danke, ich werd mich mal durchkauen!
_________________
Meine Wenigkeit im Internet: http://www.sideshow-systems.de

[Folker]

> werd mich mal durchkauen!

Ach, so wild ist das nicht - sind nur ein paar grundlegende Handler zu dem Thema Rekursion.

Gruß,
Folker
_________________
Gruß,
Folker Brandt
=============================
Systemberatung · Datenbanken · Webdesign

[sideshow]

Hallo Forum,

ich bin jetz schon ne ecke weiter, kann mir aber jemand erklären, wieso mein rechner voll abschmiert, wenn ich das script laufen lasse?

----

-- Run-Handler zum debuggen
on run
set theFileList to {}
display dialog "Ziehen Sie einen Ordner mit Files auf das Droplet und " & ¨
"geben dann einen Dateinamen ein." & return & ¨
"Die Daten werden nun benannt!" buttons {"OK"} default button 1 giving up after 20 with icon note

repeat with theFile in theFileList
File_or_Folder(theFile)
end repeat
end run

--***********************************************************************************

on open theFileList -- Per Drag & Drop wird eine Liste mit Referenzen an das Skript übergeben
repeat with theFile in theFileList
File_or_Folder(theFile)
end repeat
end open


-- Prüfung, ob es sich um einen Ordner oder eine Datei handelt
on File_or_Folder(theFile)
set theInfo to info for theFile
if folder of theInfo then -- nicht in einen Finder-Tell-Block setzen!
tell application "Finder"
-- Inhaltsliste des Unterordners erstellen
-- benötigt Finder-Tell-Block für 'every item'
set FolderList to every item of theFile
end tell
repeat with theFolder in FolderList
set theFolder to theFolder as alias -- wichtig für OS X
(* Ohne 'as alias' enthält die Variable 'theFolder' nur
     den Namen des Ordners als Unicode Text. *)
-- rekursiver Aufruf des Handlers
my File_or_Folder(theFolder)
end repeat
else
-- Kein Ordner, also Datei bearbeiten
ProcessIt(theFile)
end if
end File_or_Folder

--***********************************************************************************

-- Dateien werden bearbeitet
on ProcessIt(theFile)
tell application "Finder"
activate

--Den Dateinamen eingeben (bei mehr als 15 Zeichen nochmal neu eingeben!)
set xRepeat to 0
repeat until xRepeat = "OK"
set x_setName to display dialog "Wie sollen die Dateien heissen?" default answer "" buttons {"OK"} default button 1
set x_name to text returned of x_setName

if length of x_name <= 15 then
exit repeat
else
display dialog "Der eingegebene Name ist zu lang" & return & ¨
"(max. 15 Zeichen)!" buttons {"OK, nochmal eingeben"} default button 1 with icon stop giving up after 5
end if
end repeat

end tell
end ProcessIt

--

also ich checks nicht. vorsicht beim testen! Der Rechner hängt sich komplett auf (bei mir zumindest)! da hilft nur noch ein druck auf das neustart könpferl!
Danke schon mal im voraus!
_________________
Meine Wenigkeit im Internet: http://www.sideshow-systems.de

[Folker]

Hallo sideshow,

erstmal: IMMER EINE ABBRUCHBEDINGUNG EINBAUEN! Was meinst, mein Sohnemann haut die gesamte HD aufs Proggi - da gibt er noch in 2 Wochen Namen ein oder drückt aufs Neustart-Knöpfle ;)

Verwendest Du etwa AS Vers. 1.7 - info for ist da extrem buggy - Absturzfreudig (freeze)

Ansonsten läuft das Droplet bei mir. Allerdings: wie soll das funktionieren:
set xRepeat to 0
repeat until xRepeat = "OK"
Ich vermute, Du hast Teile des Scripts fürs Posting rausgeschmissen? xRepeat wird bei mir niemals "OK"Ö

Gruß,
Folker
_________________
Gruß,
Folker Brandt
=============================
Systemberatung · Datenbanken · Webdesign

[sideshow]

Hi Folker,

ja ich hab Version 1.7. Ich weiss nicht ob's an dem liegt. Es is halt so, ich starte des Programm, geb den Namen ein und auf einmal geht gar nix mehr. Wie würdest du das anders Programmieren? Wegen das Abbruchbedingung: da würde nach dem Eingabefenster für den Namen schon nochmal ein Warnhinweis kommen (also sowas wie: sind sie sicher... <OK> <Nö>). Ach und das mit der repeat-schleife: ist ein bisschen unglücklich programmiert. xRepeat kann auch gar nich "OK" werden. Is ja auch wurscht, weil wenn der Name kürzer als 15 Zeichen ist, verlässt er sowieso die Schleife und wenn er länger ist, dann geht er halt wieder an den Anfang. Ich hätte ja eigentlich nur ne andere Repeatanweisung schreiben müssen.

Na ja, ich versteh bloß nich wie ich des jetz hinbekommen soll! Denn wenn ich den Repeat-Teil rausnehme, dann funktionrt das Script (aber dann passiert halt nix!).

Na ja, mal sehen. Auf alle Fälle Danke für deine Hilfe und wenn dir noch ne weitere Problemlösung einfältt, dann nur her damit, ich wäre Dankbar!


Gruß, sideshow
_________________
Meine Wenigkeit im Internet: http://www.sideshow-systems.de

[Folker]

Zuerst mal auf AS 1.6 downdaten! Das wurde zwischenzeitlich selbst von Apple empfohlen - sonst vergiß info for, der sorgt fürs einfrieren, kenne ich aus leidvoller eigener Erfahrung (sollte aber mit 1.8.3 auch behoben sein)

Jaja, genau, sowas mit "Ok" und "Nö" - die Möglichkeit sollte immer gegeben sein.

Wenn im Loop keine Abbruchbedingung gebraucht wird dann einfach
repeat
if then
--
exit repeat
else
--
end if
end repeat

Ohja, es gab mal (gibt?) AS Versionen, die wenn nur 1 Datei auf Droplet fällt keine Liste übergeben sondern nur ein alias eben. Für alle Fälle würde ich immer die class abfragen.
on open the_items
if class of the_items is not list then set the_items to {the_items}

Gruß,
Folker
_________________
Gruß,
Folker Brandt
=============================
Systemberatung · Datenbanken · Webdesign

[Snow]

Hallo Sideshow,

ich stimme Folker da voll zu. Sofort eine andere AppleScript-Version!
AppleScript 1.7 war eine Fehlentwicklung.

Zu deinem Skript:
Bei mir läuft es unter AS 1.6 - allerdings tut sich außer den Namensabfragen nichts, da ja mit dem Namen nichts gemacht wird.

Ich dachte, du wolltest alle Dateien mit dem gleichen Namen und Nummerierung versehen. - Dann würde die Frage nach dem Namen am Anfang des Skripts (on open) genügen. Den Namen speicherst du in einer globalen Variablen, dann ist er auch im "ProcessIt"-Handler verfügbar, ohne dass du ihn explizit an diesen Handler übergeben musst.

Ebenfalls am Anfang des Skripts deklarierst du eine Zählvariable (theCounter o.ä.) - die setzt du auf 1
Diese Variable sollte am besten auch global sein - ist am bequemsten.

Im "ProcessIt"-Handler benötigst du jetzt nur noch die Anweisungen an den Finder, die jeweilige Datei umzubenennen.

tell application "Finder"
set the name of theFile to x_name & "_" & (items -2 thru -1 of ( "0" & tCounter))
set tCounter to tCounter + 1
end tell

Falls du noch die Dateiendung (entsprechend dem File-Type) anhängen möchtest, gehört dies auch in den "ProcessIt"-Handler, da der Filetype ja für jede Datei gesondert ermittelt werden muss.
_________________
Peter
-
Fischer-Bayern.de|Shadetreemicro.com

[sideshow]

Hi Snow,

ja du hast recht. Da muss noch das Namen & Nummern vergeben mit rein, aber angeregt von deinen Testergebnissen habe ich jetzt erst mal versucht, das Script neu aufzubauen da ich unbedingt umsetzen wollte, das man einen - Ordner -  auf das Droplet ziehen kann und nicht die Dateien an sich. Aber leider hapert es schon am Anfang. Ich habs jetz nach Folkers Tip auf 1.6 umgesichert und jetzt stürzt mein System fast noch viel gemeiner ab! Also irgendwo is da jetz der Wurm drinne. Das eigentlich Grundgerüst für das Script hab ich sowieso aus deinem "Rekursive Handler" Text. Das dumme ist nur das ich von diesem ding eigentlich (leider) fast gar nix versteh. Ich weiss bloß wie ich mein Script so ungefähr dazu pfriemeln muss.

Ich hoffe ich bekomms selber hin. Wenn nicht, dann meld ich mich nochmal!

Danke ihr  beiden!
_________________
Meine Wenigkeit im Internet: http://www.sideshow-systems.de

[Folker]

So, hier ist ein Vorschlag - wobei ich das jetzt nur auf einem 9er geprüft habe, evtl sind X Anpassungen fällig?

Achso, auf 1.6 downdaten: Standard Additions + AppleScript Extension auswechseln!

on run
set the_L to (choose folder)
open the_L
end run

on open the_L
try
global the_Count
if class of the_L is not list then set the_L to {the_L}
set the_Count to 0
get_name("Neuer Name")

repeat with i in the_L
set the_item to i
set the the_info to info for the_item
if folder of the the_info is true then
process_folder(the_item)
else --if (alias of the the_info is false) and (the file type of the the_info is in {"TIFF", "EPSF"})
process_item(the_item, file type of the_info)
end if
end repeat
on error errmsg number errnum
beep
if errnum is not -128 then display dialog errmsg buttons {"Argh!"} default button 1
end try
end open

on process_folder(the_folder)
set the_L to list folder the_folder without invisibles
repeat with i in the_L
set the_item to alias ((the_folder as text) & (contents of i))
set the the_info to info for the_item
if folder of the the_info is true then
process_folder(the_item)
else --if (alias of the the_info is false) and (the file type of the the_info is in {"TIFF", "EPSF"}) then
process_item(the_item, file type of the_info)
end if
end repeat
end process_folder

on process_item(the_file, the_Type)
global the_Count, theNewName
set the_Count to the_Count + 1
set the_name to theNewName & text -5 thru -1 of ("00000" & the_Count as string) & "." & the_Type

log the_name
tell application "Finder"
set name of the_file to the_name
end tell
end process_item

on get_name(temp)
global theNewName
repeat
set temp to (display dialog "Bitte neuen Namen eingeben:" default answer temp buttons {"Nein", "OK"} default button 2)
if button returned of temp = "Nein" then error "Benutzer bricht ab" number -128
set temp to text returned of temp
if length of temp > 15 then
display dialog "Bitte nicht mehr als 15 Zeichen!" buttons {"Nein", "Ja"} default button 2
if button returned of the result = "Nein" then error "Benutzer bricht ab" number -128
else
set theNewName to temp
exit repeat
end if
end repeat
end get_name


Nein, läuft auch unter X.1.5, AS 1.8.3 mit einer Wahnsinnsgeschwindigkeit problemlos Ö

Gruß,
Folker

(Geändert von Folker um 16:43 Uhr am 16 Juli 2002)
_________________
Gruß,
Folker Brandt
=============================
Systemberatung · Datenbanken · Webdesign

[Snow]

Hast du auch den Skripteditor von 1.6?

Zur Rekursion:
Im Prinzip besteht das Grundgerüst aus drei Teilen, die ich jetzt mal mit einer kleinen Firma vergleichen möchte:

1. on open bzw. on run - das ist die <b>Auftragsannahme</b>
2. on File_or_Folder - eine <b>Verteilerstation</b>
3. on ProcessIt - die eigentliche <b>Produktion</b>

Der Arbeitsablauf in dieser kleinen Firma sieht nun so aus:

In der Auftragsannahme geht ein Paket ein, dessen Inhalt bearbeitet werden soll. Natürlich muss hier festgestellt werden, in welcher Weise die Bearbeitung geschehen soll. Der Kunde hat ein Schreiben beigelegt, das besagt, dass die im Paket enthaltenen Dateien einen einheitlichen Namen jedoch mit aufsteigender Nummerierung und einer Dateiendung entsprechend dem Dateityp erhalten sollen. Da in der Auftragsannahme jedoch niemand weiß, wie die Dateien heißen sollen, wird beim Kunden nachgefragt. Während dieser Nachfrage wird dann auch gleich geprüft, ob man dem Wunsch des Kunden nachkommen kann, da die Maschinen in der Produktion nur Dateinamen mit einem Namensbestandteil von höchstens 15 Zeichen herstellen können. - Nachdem man sich mit dem Kunden geeinigt hat, ist es noch Aufgabe der Auftragsannahme, das Paket und die zugehörigen Informationen weiter zu leiten.
Dies kann nun auf zwei Arten geschehen:
1. Die Daten werden dem Paket beigefügt und mit ihm weitergereicht (das wäre der Fall, wenn man die entsprechenden Daten beim Handler-Aufruf mit übergibt)
2. Die Daten werden direkt an die anderen Abteilungen geschickt (Definition der entsprechenden Variablen als global - am Anfang des Skripts - außerhalb des "on open"-Handlers)

Unser Paket landet jetzt in der Verteilerstation. Hier sitzen zwei Leute. Der erste hat nur die Aufgabe, das Paket zu öffnen, der zweite schaut dann nach was sich darin befindet. Findet er Dateien vor, schickt er sie gleich weiter (eine nach der anderen) an die Produktion. Trifft er jedoch auf ein weiteres Paket (im Paket), gibt er es an den ersten Mann zurück, damit dieser es öffnet. Vorgefundene Dateien gehen wieder an die Produktion, weitere Pakete bekommt immer der erste Arbeiter zum Öffnen. - Das ist die eigentliche Rekursion!

In der letzten Station unserer Firma wird die Ware dann bearbeitet. Die Produktionsabteilung hat von der Auftragsannahme bereits den vom Kunden gewünschten Dateinamen und die Information, dass die Nummerierung mit "01" beginnen soll erhalten. Sobald die erste Datei von der Verteilerstelle eintrifft, beginnt die Produktion. Für die Datei-Endung wird der Dateityp ermittelt und die "Dateinamen-Maschine" wird entsprechend eingestellt. Nachdem der erste Dateiname fertig ist, wird der Zähler um 1 höher gestellt. So werden alle eintreffenden Dateien behandelt, bis keine Datei mehr eintrifft. Dann gönnen sich alle erst mal eine Pause bis zum nächsten Auftrag.
_________________
Peter
-
Fischer-Bayern.de|Shadetreemicro.com

[sideshow]

Hab jetz mal n bissl rumgeschaut und festgestellt, das es vor allem daran lag, dass das update auf 9.2.2 von 9.2.1, Apple Script 1.7 installiert hat und das war der Fehler.

Jetz is alles wieder gut und funktioniert wieder! 1.6 läuft doch um einiges besser (scheinbar).
_________________
Meine Wenigkeit im Internet: http://www.sideshow-systems.de

[Folker]

Ha, ja - ich glaube Herr Espinosa war es seinerzeit, der die Ankündigung machte (im Februar?), dass alle neuen CPU ab dem Zeitpunkt mit AS 1.6 ausgeliefert würden, aber das Update auf 9.2.2 sei ja nun mal so und Apple würde auf seinen Seiten einen Hinweis geben wie auf 1.6 downzudaten (kann man das so sagen?) ist. Habe niemals den Hinweis gefunden (allerdings auch nicht gründlich gesucht). Die Tatsache mit dem "schrotten" 1.7 war zwar den Pro-Usern, welche sich in einschl. Newsgroups aufhalten, bekannt aber der "normale" Kunde sucht wahrscheinlich Tage nach der Ursache des plötzlichen "info for freeze" Ö

Gruß,
Folker
_________________
Gruß,
Folker Brandt
=============================
Systemberatung · Datenbanken · Webdesign

[sideshow]

Guten Morgen,

So weit bin ich mit dem (Roh)Script schon:

---------
property tCounter : 1


-- Run-Handler zum debuggen
on run
set theFileList to {} --(choose folder) as list
display dialog "Ziehen Sie einen Ordner mit Files auf das Droplet und " & ¨
"geben dann einen Dateinamen ein." & return & ¨
"Die Daten werden nun benannt!" buttons {"OK"} default button 1 giving up after 20 with icon note

repeat with theFile in theFileList
File_or_Folder(theFile)
end repeat

end run



on open theFileList -- Per Drag & Drop wird

-- eine Liste mit Referenzen an das Skript übergeben
repeat with theFile in theFileList
File_or_Folder(theFile)
end repeat

end open


-- Prüfung, ob es sich um einen Ordner oder eine Datei handelt
on File_or_Folder(theFile)
set theInfo to info for theFile
if folder of theInfo then -- nicht in einen Finder-Tell-Block setzen!
tell application "Finder"
-- Inhaltsliste des Unterordners erstellen
-- benötigt Finder-Tell-Block für 'every item'
set FolderList to every item of theFile
end tell
repeat with theFolder in FolderList
set theFolder to theFolder as alias -- wichtig für OS X
(* Ohne 'as alias' enthält die Variable 'theFolder' nur
     den Namen des Ordners als Unicode Text. *)
-- rekursiver Aufruf des Handlers
my File_or_Folder(theFolder)
end repeat
else
-- Kein Ordner, also Datei bearbeiten
ProcessIt(theFile)
end if
end File_or_Folder


-- Dateien werden bearbeitet
on ProcessIt(theFile)
tell application "Finder"

--der Datei den Namen "Ohne Titel" geben wenn x_name = ""
if x_name = "" then
set x_name to "Ohne Titel"
end if

tell application "Finder"
set the name of theFile to x_name & "_" & (items -2 thru -1 of ("0" & tCounter))
set tCounter to tCounter + 1
end tell

end tell
end ProcessIt
---------

Jetzt hab ich nur noch das Problem, wo dieser Teil rein muss:

------
tell application "Finder"
activate
--Den Dateinamen eingeben (bei mehr als 15 Zeichen nochmal neu eingeben!)
repeat
set x_setName to display dialog "Wie sollen die Dateien heissen?" default answer ""
set x_name to text returned of x_setName

if length of x_name <= 15 then
exit repeat
else
display dialog "Der eingegebene Name ist zu lang" & return & ¨
"(max. 15 Zeichen)!" buttons {"OK, nochmal eingeben"} default button 1 with icon stop giving up after 5
end if
end repeat
end tell
------

Da ja die Variable "x_name" fürs ganze Script gelten soll! Wo muss ich diesen Teil einfüge, oder wie geht des mit der globalen Variable genau?

Danke im Voraus!

Grüße sideshow
_________________
Meine Wenigkeit im Internet: http://www.sideshow-systems.de