Fischer-Bayern.de
 FAQFAQ   SuchenSuchen   MitgliederlisteMitgliederliste   BenutzergruppenBenutzergruppen   RegistrierenRegistrieren 
 ProfilProfil   Einloggen, um private Nachrichten zu lesenEinloggen, um private Nachrichten zu lesen   LoginLogin 

Ordnerstruktur anlegen - kann man da noch was verbessern?

 
Neues Thema eröffnen   Neue Antwort erstellen    Fischer-Bayern.de Foren-Übersicht -> AppleScript X
Vorheriges Thema anzeigen :: Nächstes Thema anzeigen  
Autor Nachricht
macrip
•->
•->


Anmeldedatum: 20.03.2009
Beiträge: 13
Wohnort: 92709 Moosbach

BeitragVerfasst am: 05.04.2009 - 15:27    Titel: Ordnerstruktur anlegen - kann man da noch was verbessern? Antworten mit Zitat

Hallo zusammen,

ich hab vor längerer Zeit einem Kollegen mal ein Script erstellt, um eine duchnummerierte Ordnerstruktur anzulegen, die folgenden Aufbau hat:

FOTOREISE ---> Ordner ---> Ordner -A01, ...-A02, ...-A03, usw.

Im den nummerierten Unterordnern befinden sich jeweils die Ordner VORAUSWAHL, ENDAUSWAHL, REST sowie eine vorgefertige Datei "iview.ivc", die dem Script (als Programmbundle gesichert) im Resources-Ordner beiliegt und ebenfalls nummeriert wird.

Jetzt ist es mir vor kurzem mal wieder vor die Flinte gelaufen und ich hab am ursprünglichen Script ein wenig gebastelt und es noch ein wenig verbessert (z.b. die iview-Datei im Bundle integriert). Das Script an sich läuft soweit ohne Probleme - wenn auch bei vielen zu erstellenden Ordnern doch ein wenig langsam - und ich bin eigentlich recht zufrieden damit. Mich würde aber trotzdem mal interessieren, was die Profis hier dazu sagen und ob man da noch was optimieren könnte - man lernt ja nie aus Very Happy

Code:
with timeout of 3600 seconds
   run OrdnerFotoreise
   run iFolder
   repeat
      tell application "Finder"
         activate
         display dialog "Die gewünschten Ordner wurden erstellt! Soll eine neue Ordnerstruktur angelegt werden?" buttons {"Beenden", "Neue Ordnerstruktur"} default button 2
         set theButtonPressed to button returned of the result
         if the theButtonPressed is "Beenden" then
            exit repeat
         end if
         if the theButtonPressed is "Neue Ordnerstruktur" then
            run iFolder
         end if
      end tell
   end repeat
end timeout


script OrdnerFotoreise
   tell application "Finder"
      try
         set ordnerAuswahl to (path to "desk" as string) & "FOTOREISE:" as alias
         set label index of ordnerAuswahl to 2
      on error
         make new folder at desktop with properties {name:"FOTOREISE"}
         set ordnerAuswahl to (path to "desk" as string) & "FOTOREISE:" as alias
         set label index of ordnerAuswahl to 2
      end try
   end tell
end script




script iFolder
   tell application "Finder"
      set ordnerAuswahl to (path to "desk" as string) & "FOTOREISE:" as alias
      display dialog "Bitte geben Sie die gewünschte Ordnerbezeichnung an:" default answer "" buttons {"Cancel", "Ok"} default button 2
      set ordnerName to the text returned of the result
      
      repeat
         try
            make new folder at ordnerAuswahl with properties {name:ordnerName}
            exit repeat
         on error
            display dialog "Dieser Ordner existiert bereits!" & return & "Bitte wählen Sie eine andere Bezeichung:" default answer "" buttons {"Cancel", "Ok"} default button 2
            set ordnerName to the text returned of the result
         end try
      end repeat
      
      display dialog "Wieviele Ordner möchten Sie erstellen?" default answer "" buttons {"Cancel", "Ok"} default button 2
      set ordnerZaehler to (text returned of the result) as integer
      set ordner to (path to "desk" as string) & "FOTOREISE:" & ordnerName & ":" as alias
      set Resource to ((path to me as text) & "Contents:Resources:iview.ivc")
      set dateiname to "iview.ivc"
      
      repeat with i from 1 to ordnerZaehler by 1
         if i < 10 then
            set OrdnerNummer to (characters 2 thru 3 of (i + 100 as string)) as string
         else
            set OrdnerNummer to i
         end if
         make new folder at (ordner) with properties {name:((ordnerName & "-A" & OrdnerNummer) as string)}
         make new folder at folder (ordnerName & "-A" & OrdnerNummer) of folder (ordner) with properties {name:"REST"}
         make new folder at folder (ordnerName & "-A" & OrdnerNummer) of folder (ordner) with properties {name:"VORAUSWAHL"}
         make new folder at folder (ordnerName & "-A" & OrdnerNummer) of folder (ordner) with properties {name:"ENDAUSWAHL"}
         duplicate Resource to folder (ordnerName & "-A" & OrdnerNummer) of folder (ordner)
         set name of file ((ordner & ordnerName & "-A" & OrdnerNummer & ":" & dateiname) as string) to (ordnerName & "-A" & OrdnerNummer) & ".ivc"
      end repeat
   end tell
end script



Wer möchte, kann sich das fertige Bundle auch downloaden




Edit sagt:

Eins hab ich noch vergessen - gäb's denn irgend ne Möglickeit, eine Art Fortschrittsbalken oder -anzeige in dieses Script zu integrieren (ohne ASS, da kenn ich mich net aus mit). Ich dachte da z.B. an Growl - da hab ich's zwar bereits versucht, bekomme es aber nur so hin, das Growl bei jedem erstellen Ordner aufpoppt, naja und bei 100 Ordnern is das ziemlich nervig und hängt ewig hinterher. Schöner wäre es, wenn Growl nur einmal aufpoppt und da dann der Gesamtfortschritt abläuft.
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden
Wolle-77
•--->
•--->


Anmeldedatum: 25.02.2003
Beiträge: 447
Wohnort: Geldern

BeitragVerfasst am: 06.04.2009 - 11:32    Titel: Antworten mit Zitat

Hallo macrip,

ich mag AppleScript sehr gerne (sonst wäre ich auch kaum hier), aber das scheinbar zentralste Element unseres geliebten Systems Mac OS X – der Finder selbst – gehört noch (mindestens bis zum Erscheinen von 10.6, Snow Leopard) zu den trägsten und langsamsten Befehlsempfängern. Daher würde ich bestimmte Aufgaben (nicht alle) am Finder vorbei erledigen und – das ist ja kein Widerspruch zu AppleScript, im Gegenteil, es ist eine Kupplung zu einer weiteren riesigen Welt – das via Shell erledigen.

Das einzige, was dort wohl nicht geht, ist das Setzen des orangen Etikettes des Hauptordners. Aber ansonsten schrumpft Dein Script auf einen Einzeiler und zudem wirst Du keinen Fortschrittsbalken mehr benötigen, da das Ganze bei meinen 100 Testordnern in weniger als einer Sekunde fertig ist (mein alter iMac 17 " weiß):

Code:
do shell script "mkdir -p ~/FOTOREISE/Meins ; cd ~/FOTOREISE/Meins ; for i in {1..100} ; do mkdir -p Meins-$i/{ENDAUSWAHL,REST,VORAUSWAHL} ; touch Meins-$i/Meins-$i.ivc ; done"


Die Erklärung: Das ganze ist ein einzeiliges Shell-Script. Die einzelnen Befehlsabschnitte werden mit Semikolon ; getrennt.
1. mkdir -p ~/FOTOREISE/Meins
Damit wird in Deinem Benutzerordner (~) Dein Ordner Fotoreise mit dem Wunsch-Unterordner erzeugt. Durch Verwendung des Schalters -p braucht sich um das Anlegen der Elternordner generell nicht gekümmert werden, sie werden gleich mit angelegt.
2. cd ~/FOTOREISE/Meins
Wir gehen in den gerade erzeugten Unterordner hinein.
3. for i in {1..100}
Es wird eine Schleife eingeleitet mit der Variablen i. i wird also von 1 bis 100 durchgezählt, alle Befehle in der Schleife 100 Mal ausgeführt.
4. do mkdir -p Meins-$i/{ENDAUSWAHL,REST,VORAUSWAHL}
Pro Durchgang wird der Ordner Meins-i angelegt und in ihm die drei gewünschten Unterordner.
5. touch Meins-$i/Meins-$i.ivc
Zusätzlich wird in pro Unterordner Deine gewünschte ivc-Datei angelegt. Da mit touch ein besseres Werkzeug zur Verfügung steht, um leere Dateien anzulegen, braucht keine leere Datei kopiert und dann umbenannt zu werden.
6. done
Wie der Name besagt, so wird hiermit die Schleife beendet.

Es entstehen somit auf einen Schlag 501 Objekte. Der Rest ist Beiwerk – Du kannst die Anzahl der Objekte trotzdem via display dialog abfragen und das Ergebnis in den String, den do shell script ausführt, einbauen:
Code:
set ergebnis to 50
do shell script "echo {1.." & ergebnis & "}"


Zählt beispielsweise bis 50…

Ich hoffe, daß Du zufrieden bist…

Zwei Dinge sind zu unserer Arbeit nötig:
Unermüdliche Ausdauer und die Bereitschaft, etwas, in das man viel Zeit und Arbeit gesteckt hat, wieder wegzuwerfen.

_________________
Martin Wolter
--
Apple rocks the planet!
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden
iScript
•---->
•---->


Anmeldedatum: 29.03.2001
Beiträge: 1116

BeitragVerfasst am: 06.04.2009 - 21:47    Titel: Antworten mit Zitat

eine ähnlichen ansatz wie wolle hatte ich auch mit dem mkdir -p.
hatte gestern abend schon mal etwas angefangen das umzufrickeln und es heute mal vollendet. die schleife ist bei mir allerdings eine applescript-schleife, weshalb das script vielleicht etwas langsamer als wolle's lösung sein wird. hier mein vorschlag. das sollte auch einigermaßen sonderzeichen-sicher sein. einen slash ("/") sollte man allerdings nicht im ordnernamen verwenden:

with timeout of 3600 seconds
   run iFolder
   repeat
      tell application "Finder"
         activate
         set theButtonPressed to button returned of (display dialog ¬
            "Die gewünschten Ordner wurden erstellt! Soll eine neue Ordnerstruktur angelegt werden?" buttons ¬
            {"Beenden", "Neue Ordnerstruktur"} default button 2)
      end tell
      if theButtonPressed is "Beenden" then exit repeat
      if theButtonPressed is "Neue Ordnerstruktur" then run iFolder
   end repeat
end timeout


script iFolder
   set oName to the text returned of (display dialog ¬
      "Bitte geben Sie die gewünschte Ordnerbezeichnung an:" default answer "" buttons {"Cancel", "Ok"} default button 2)
   set oZaehler to (text returned of (display dialog ¬
      "Wieviele Ordner möchten Sie erstellen?" default answer "" buttons {"Cancel", "Ok"} default button 2)) as integer
   set myRes to ((path to me as text) & "Contents:Resources:iview.ivc")
   repeat with i from 1 to oZaehler
      set oNumber to (text -2 thru -1 of ("0" & i))
      set rootFolder to POSIX path of (path to "desk" as string) & "FOTOREISE/" & oName & "/"
      set mycommand to "mkdir -p " & ¬
         quoted form of (rootFolder & oName & "-A" & oNumber) & "/{REST,VORAUSWAHL,ENDAUSWAHL}" & ¬
         "; cp " & quoted form of (POSIX path of myRes) & " " & ¬
         quoted form of (rootFolder & oName & "-A" & oNumber & "/" & oName & "-A" & oNumber & ".ivc")
      do shell script mycommand
   end repeat
end script
_________________
- anholn deit kriegen -
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden Website dieses Benutzers besuchen AIM-Name
macrip
•->
•->


Anmeldedatum: 20.03.2009
Beiträge: 13
Wohnort: 92709 Moosbach

BeitragVerfasst am: 06.04.2009 - 23:25    Titel: Antworten mit Zitat

Omg Shocked - ich bin schwer begeistert. Jetzt dachte ich, ich hätt's eigentlich für meine Kenntnisse doch ganz annehmbar hinbekommen, aber das man das ganze so extrem optimieren kann hätt ich mir nicht träumen lassen. Dickes Danke schon mal an Euch beide!

Wolles Code werd ich mir mal in Ruhe näher anschauen und versuchen, mich mal Shell ein wenig anzunähern. Was das angeht, bin ich noch ziemlich jungfräulich, aber die Befehle scheinen ja doch sehr mächtig zu sein, wie ich das bisher mitbekommen habe.


@iScript: Also Dein Script ist auf jeden Fall wesentlich schneller als meins und auf ein "/" kann ich gut verzichten Wink . Mir sind nur 2 Dinge aufgefallen, als ich's grad laufen hab lassen.

Wenn das Script durch ist und ich möchte über den Button "Neue Ordnerstruktur" weitere Ordner anlegen, verschwindet das Fenster komischerweise im Hintergrund und das Dockicon springt. Ich muss das Fenster dann erst wieder per Mausklick nach vorne holen, um weiter machen zu können. Außerdem werden bei Deiner Lösung Ordner überschrieben, falls der gleiche Name nochmals verwendet wird.




Noch ne Frage: ich vermute mal, es wird wohl nur mit ASS machbar sein, die beiden Variablen Ordnername und Anzahl auf einmal, also in einer einzigen Dialogbox abzufragen? Studio kenn ich mich halt überhaupt net aus und möcht mich erst mal nach und nach ins AS einarbeiten.
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden
iScript
•---->
•---->


Anmeldedatum: 29.03.2001
Beiträge: 1116

BeitragVerfasst am: 06.04.2009 - 23:37    Titel: Antworten mit Zitat

um das script nach vorn zu holen, füge einfach ein "activate me" vor dem dialog ein, dann kommt das script in den vordergrund.

das mit dem überschreiben bestehender ordner stimmt so nicht: es werden nur ordner angelegt (option -p), wenn sie noch nicht vorhanden sind. du brauchst also keine angst haben, das bestehende dateien in den ordnern dadurch gelöscht werden. diese methode bietet ganz im gegenteil sogar noch einen mehrwert. stell dir vor, du hast schon einen ordner mit 30 unterordnern erstellen lassen und befüllt, und du merkst, du brauchst noch 20 mehr, dann startest du einfach nochmal das script, gibst den gleichen ordnernamen an und setzt die anzahl von unterordnern auf 50, dann werden die fehlenden 20 ordner hinzugefügt. und falls ordner in dem bereich gelöscht wurden, werden diese ebenfalls wieder angelegt, so dass du auf jeden fall 50 subfolder hast. probiers mal aus.

und mit den 2 dialogen in einem dialog hast du recht. das geht nicht mit purem applescript.
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden Website dieses Benutzers besuchen AIM-Name
macrip
•->
•->


Anmeldedatum: 20.03.2009
Beiträge: 13
Wohnort: 92709 Moosbach

BeitragVerfasst am: 06.04.2009 - 23:45    Titel: Antworten mit Zitat

Ok, Du hast mich überzeugt - läuft echt super, und der Mehrwert Deines Scripts ist echt nicht ohne.

Aber unabhängig von der Geschwindigkeit etc - war ich denn wirklich recht umständlich mit meinem Versuch eines Scripts? Oder kann man das für einen mittelmäßig begabten Scripter durchgehen lassen?
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden
iScript
•---->
•---->


Anmeldedatum: 29.03.2001
Beiträge: 1116

BeitragVerfasst am: 07.04.2009 - 20:30    Titel: Antworten mit Zitat

nö, an deinem script ist (bis auf die geschwindigkeit) fast nichts auszusetzen, zumal es tut ja, wie es soll. also ich lass dir das so durchgehen Wink
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden Website dieses Benutzers besuchen AIM-Name
Wolle-77
•--->
•--->


Anmeldedatum: 25.02.2003
Beiträge: 447
Wohnort: Geldern

BeitragVerfasst am: 08.04.2009 - 11:46    Titel: Hm... Antworten mit Zitat

Hallo iScript, macrip,

wenn ich da mal Einsenfen darf, das sehe ich ein klein wenig anders.

Ich würde hier und da einige Dinge ändern, weil ich sie für sauberer (und kürzer) halte.

Punkt 1:

Code:
display dialog "Die gewünschten Ordner wurden erstellt! Soll eine neue Ordnerstruktur angelegt werden?" buttons {"Beenden", "Neue Ordnerstruktur"} default button 2
         set theButtonPressed to button returned of the result
         if the theButtonPressed is "Beenden" then
            exit repeat
         end if
         if the theButtonPressed is "Neue Ordnerstruktur" then
            run iFolder
         end if


Solche Dinge sollte man so bauen:

Code:
set abfr to button returned of (display dialog "Die gewünschten Ordner wurden erstellt! Soll eine neue Ordnerstruktur angelegt werden?" buttons {"Beenden", "Neue Ordnerstruktur"} default button 2 giving up after 120)
if abfr is "Beenden" then
   exit repeat
else
   run iFolder
end if


Mit result zu arbeiten, kann hakelig werden und sollte nur im Notfall gemacht werden.

Übrigens gibt es bei if..else auch einzeilige Varianten: if ... then beep.

Also end if (bzw. die mindestens drei Zeilen) ist nicht immer notwendig.

Punkt 2:

Code:
   tell application "Finder"
      try
         set ordnerAuswahl to (path to "desk" as string) & "FOTOREISE:" as alias
         set label index of ordnerAuswahl to 2
      on error
         make new folder at desktop with properties {name:"FOTOREISE"}
         set ordnerAuswahl to (path to "desk" as string) & "FOTOREISE:" as alias
         set label index of ordnerAuswahl to 2
      end try
   end tell


Sollte geändert werden zu:

Code:
tell application "Finder"
   try
      make new folder at desktop with properties {name:"FOTOREISE"}
   end try
   set ordnerAuswahl to (path to "desk" as string) & "FOTOREISE:" as alias
   set label index of ordnerAuswahl to 2
end tell


Also immer nur die Script-Teile, die einen Fehler liefern könnten, in ein try-Statement packen – nicht alles doppelt.

In dem Fall zwar egal (bis auf die drei nicht nötigen Zeilen Code), aber bei größeren Scripten kommst Du total durcheinander und weißt nicht mehr, welcher Teil (im Try- oder im Error-Teil) nun gearbeitet hat und wo nun evtl. Nachfolgefehler liegen.

Punkt 3:

Code:
      display dialog "Wieviele Ordner möchten Sie erstellen?" default answer "" buttons {"Cancel", "Ok"} default button 2
      set ordnerZaehler to (text returned of the result) as integer


Das würde ich beispielsweise unbedingt prüfen. Stell Dir vor, der Benutzer gibt eine "3+" ein (weil er beim Return-Drücken abgerutscht ist...) – dann stehst Du da.

Also so:

Code:
repeat
   set abfr to text returned of (display dialog "Wieviele Ordner möchten Sie erstellen?" default answer "" buttons {"Abbrechen", "Ok"} default button 2 giving up after 120)
   try
      set ordnerZaehler to abfr as integer
      exit repeat
   end try
end repeat


Dann kommt der Nutzer ohne nervige Fehlermeldungen nur weiter, wenn er eine Zahl eingibt – ohne langen Scriptaufwand.

Punkt 4: (Dann soll es aber auch gut sein ;-)

Solche Dinge hier:

Code:
make new folder at folder (ordnerName & "-A" & OrdnerNummer) of folder (ordner) with properties {name:i}
make new folder at folder (ordnerName & "-A" & OrdnerNummer) of folder (ordner) with properties {name:"VORAUSWAHL"}
make new folder at folder (ordnerName & "-A" & OrdnerNummer) of folder (ordner) with properties {name:"ENDAUSWAHL"}


Also wo sich große Teile ähneln, da würde ich prinzipiell redundant arbeiten:

Code:
set meineunterordner to {"REST", "VORAUSWAHL", "ENDAUSWAHL"}
repeat with i in meineunterordner
make new folder at folder (ordnerName & "-A" & OrdnerNummer) of folder (ordner) with properties {name:i}
end repeat

Du siehst, der wesentliche Teil ist nur einmal im Quellcode vorhanden und kann so auch besser gepflegt werden, falls mal Änderungen erforderlich sind.


Alle Punkte gelten natürlich für alle Vorkommen.

So, genug geklugscheißert, aber ich denke, Du wirst das bei großen Projekten noch zu schätzen wissen...
_________________
Martin Wolter
--
Apple rocks the planet!
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden
macrip
•->
•->


Anmeldedatum: 20.03.2009
Beiträge: 13
Wohnort: 92709 Moosbach

BeitragVerfasst am: 09.04.2009 - 07:48    Titel: Antworten mit Zitat

Wow, vielen Dank für Dein "geklugscheiße". Da kann ich mir bestimmt einiges abschauen. Sieht so auf jeden Fall viel aufgeräumter auf - da hat's wirklich gefehlt an meinem ursprüngliche Code. Werd mir das am Wochenende mal in Ruhe zu Gemüte führen.

Dein shell script hab ich inzwischen auf soweit gebracht, das es mit Dialogen etc. läuft. Das ganze ist ja wirlich ultraschnell. Das einzige, noch fehlt, ist die iview-Datei. Mit Deinem Befehl touch Meins-$i/Meins-$i.ivc wird ja eine neue, leere Datei angelegt. Ich brauch aber zwingend eine vorgefertigte Datei, in der schon einige Einstellungen vorgenommen sind. Wie würde den der Befehl lauten, um diese Datei aus dem Resources-Ordner zu kopieren wie im ursprünglichen Script? Der Befehl aus iScript's Code
Code:
cp " & quoted form of (POSIX path of myRes) & " " & ¬
         quoted form of (rootFolder & oName & "-A" & oNumber & "/" & oName & "-A" & oNumber & ".ivc")
denke ich kommt dem schon nahe, ich krieg den aber in der Form nicht in Dein Script eingebaut. Vielleicht würdest mir den richtigen Befehl noch verraten. Wobei ich ja vermute, dass dieser Kopiervorgang dann den ursprünglichen Geschwindigkeitsvorteil wieder zunichte machen würde, oder?
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden
Wolle-77
•--->
•--->


Anmeldedatum: 25.02.2003
Beiträge: 447
Wohnort: Geldern

BeitragVerfasst am: 09.04.2009 - 11:40    Titel: Antworten mit Zitat

Hallo macrip,

das Problem Deiner Datei verstehe ich nicht – diese ist doch in Deinem Bundle ebenfalls eine 0 Byte goße, also leere Datei!?!?

Oder war Dein Bundle nur ein Beispielprogramm?

Du hast zwei Möglichkeiten: Wenn Du weißt, was in der Datei drinstehen muß und dies nicht gerade Binärdaten oder Daten in der Resource-Fork sind, kann man problemlos anstatt des touch ein echo '...' > datei einbauen.
Oder man ermittelt (durch Deinen Dialog kommst Du ja eh nicht mehr mit einer Zeile aus) vorher den Pfad zum Programmort zur Laufzeit und baut dann ein cp Quelle Ziel ein.

Also cp ist der Befehl zum Kopieren einer Datei und echo gibt Dir etwas auf die Standardausgabe aus, welches man dann mit > (welches zur Shell gehört und nichts mit dem Befehl selbst zu tun hat) in eine Datei (und nicht auf die Standardausgabe) umleiten, sprich, in eine Datei schreiben, kann.
_________________
Martin Wolter
--
Apple rocks the planet!
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden
macrip
•->
•->


Anmeldedatum: 20.03.2009
Beiträge: 13
Wohnort: 92709 Moosbach

BeitragVerfasst am: 14.04.2009 - 00:26    Titel: Antworten mit Zitat

Die Datei im Bundle war nur zum testen, normalerweise liegt da eine iview-Datei mit diversen Voreinstellungen drin, die ich zwingend brauche. Deswegen muss ich die auch kopieren. Danke für den Befehl, ich werd mich mal daran versuchen.
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden
-hans-
•-->
•-->


Anmeldedatum: 30.04.2009
Beiträge: 45

BeitragVerfasst am: 23.05.2010 - 12:18    Titel: Antworten mit Zitat

Code:
do shell script "mkdir -p ~/FOTOREISE/Meins ; cd ~/FOTOREISE/Meins ; for i in {1..100} ; do mkdir -p Meins-$i/{ENDAUSWAHL,REST,VORAUSWAHL} ; touch Meins-$i/Meins-$i.ivc ; done"


Hallo zusammen,

bei mir funktioniert diese Shell-Schleife irgendwie nicht ...
Es wird lediglich ein Unterordner mit dem Namen "Meins-{1..100}" angelegt¿
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden
iScript
•---->
•---->


Anmeldedatum: 29.03.2001
Beiträge: 1116

BeitragVerfasst am: 02.06.2010 - 22:34    Titel: Antworten mit Zitat

welches OS?
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden Website dieses Benutzers besuchen AIM-Name
-hans-
•-->
•-->


Anmeldedatum: 30.04.2009
Beiträge: 45

BeitragVerfasst am: 03.06.2010 - 22:39    Titel: Antworten mit Zitat

10.4.11 Embarassed
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden
iScript
•---->
•---->


Anmeldedatum: 29.03.2001
Beiträge: 1116

BeitragVerfasst am: 08.06.2010 - 21:49    Titel: Antworten mit Zitat

also hier klappt's. 10.6.3
vielleicht ist die zeile zu lang für die shell?

ist das noch die sh unter 10.4? oder schon die bash?
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden Website dieses Benutzers besuchen AIM-Name
Beiträge der letzten Zeit anzeigen:   
Neues Thema eröffnen   Neue Antwort erstellen    Fischer-Bayern.de Foren-Übersicht -> AppleScript X Alle Zeiten sind GMT + 2 Stunden
Seite 1 von 1

 
Gehe zu:  
Du kannst keine Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum nicht antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.


Powered by phpBB © 2001, 2002 phpBB Group
Deutsche Übersetzung von phpBB.de


AppleScript für absolute Starter