Fischer-Bayern.de
 FAQFAQ   SuchenSuchen   MitgliederlisteMitgliederliste   BenutzergruppenBenutzergruppen   RegistrierenRegistrieren 
 ProfilProfil   Einloggen, um private Nachrichten zu lesenEinloggen, um private Nachrichten zu lesen   LoginLogin 

Fehlermeldung -1296

 
Neues Thema eröffnen   Neue Antwort erstellen    Fischer-Bayern.de Foren-Übersicht -> AppleScript X
Vorheriges Thema anzeigen :: Nächstes Thema anzeigen  
Autor Nachricht
Uli
•-->
•-->


Anmeldedatum: 07.01.2008
Beiträge: 22
Wohnort: Hamburg

BeitragVerfasst am: 04.07.2008 - 17:11    Titel: Fehlermeldung -1296 Antworten mit Zitat

Hallo,

ich habe ein Script zum konvertieren von Dateien in Freehand MX geschrieben, das auch super läuft.
Jetzt wollte ich es einer Kollegin in Östereich zur Verfügung stellen, allerdings bekommt sie immer nur die Fehlermeldung:

Das Skript "droplet" konnte nicht ausgeführt werden, da ein
Programmfehler aufgetreten ist.
Fehlercode: -1264


Die Gute hat Ihren Rechner komplett durchgecheckt, ein Testscript mit "activate" zeigt auch, das Freehand angesprochen wird.
Nur weiter sind wir nicht gekommen. Wir beide arbeiten mit Tiger, ich auf G5, sie auf G4.

Kann uns jemand weiterhelfen???

Danke und Gruß
Uli
_________________
E>0 = mc2/:-)
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden
chebfarid
•-->
•-->


Anmeldedatum: 10.02.2007
Beiträge: 106
Wohnort: Milano

BeitragVerfasst am: 07.07.2008 - 18:35    Titel: Antworten mit Zitat

Schwer zu sagen, aber es scheint kein AppleScript- oder AppleEvent-Error zu sein: deren Errorcodes liegen respektive im -1700 und -2700 Range.
Hast Du schon versucht, Deiner Kollegin nur den Code des Applescripts zu schicken und ihn dann auf ihrem Mac im Scripteditor zu kompilieren?

Ciao
Farid
_________________
Abends lustig morgens triste
Das ist Leben von Artiste
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden Website dieses Benutzers besuchen
Uli
•-->
•-->


Anmeldedatum: 07.01.2008
Beiträge: 22
Wohnort: Hamburg

BeitragVerfasst am: 08.07.2008 - 10:08    Titel: Antworten mit Zitat

chebfarid hat Folgendes geschrieben:
Hast Du schon versucht, Deiner Kollegin nur den Code des Applescripts zu schicken und ihn dann auf ihrem Mac im Scripteditor zu kompilieren?


Ja, das haben wir auch schon versucht.
Trotzdem Danke und Gruß,
Uli
_________________
E>0 = mc2/:-)
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden
chebfarid
•-->
•-->


Anmeldedatum: 10.02.2007
Beiträge: 106
Wohnort: Milano

BeitragVerfasst am: 08.07.2008 - 17:22    Titel: Antworten mit Zitat

Gleiche Freehand-Version auf beiden Macs ?

Ciao
Farid
_________________
Abends lustig morgens triste
Das ist Leben von Artiste
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden Website dieses Benutzers besuchen
Uli
•-->
•-->


Anmeldedatum: 07.01.2008
Beiträge: 22
Wohnort: Hamburg

BeitragVerfasst am: 09.07.2008 - 10:11    Titel: Antworten mit Zitat

Jau!
_________________
E>0 = mc2/:-)
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden
chebfarid
•-->
•-->


Anmeldedatum: 10.02.2007
Beiträge: 106
Wohnort: Milano

BeitragVerfasst am: 09.07.2008 - 14:29    Titel: Antworten mit Zitat

Dann zeig' uns doch einfach mal den Code... Wink

Ciao
Farid
_________________
Abends lustig morgens triste
Das ist Leben von Artiste
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden Website dieses Benutzers besuchen
Uli
•-->
•-->


Anmeldedatum: 07.01.2008
Beiträge: 22
Wohnort: Hamburg

BeitragVerfasst am: 09.07.2008 - 15:16    Titel: Antworten mit Zitat

chebfarid hat Folgendes geschrieben:
Dann zeig' uns doch einfach mal den Code...


Ääääh, na gut, ist etwas länger geworden:
Code:

--Dieses Droplet wandelt alle früheren Freehand Dateien ab Version 7 in MX Dateien
--ahem - vorausgesetzt, die Dateiendungen sind korrekt oder es sind Mac Dateien :-)
--09.01. - 08.02.2008 Uli Blum - Berendohn AG
global errorListe
global errorYes
global allFiles
global countAll --sollte alle durchgelaufene Objekte zählen, zählt aber bisher alles Mögliche
global countConv --zählt alle konvertierte Objekte
global countNotConv --zählt alle nichtkonvertierte Objekte
global countIsMX --zählt alle nichtkonvertierte Objekte, die schon MX-Dateien sind
global countIsAsMX --zählt alle nichtkonvertierte Objekte, die schon als MX-Datei vorhanden sind

-------- Anmerkung zu den Countern und Rückmeldungen: sobald es Unterordner gibt, werden die Dateien dort
-------- vernünftig bearbeitet, aber die Counter und Rückmeldungen stimmen nicht!!!!
-------- Daher mußte ich auf besssere Dialoge verzichten *schnief, naja*
on run
   display dialog "Script Version 0.2" & return & return & ¬
      "Die zu konvertierenden FreeHand-
Dokumente (oder Ordner mit FreeHand-Dokumenten) auf das Icon dieses Droplets ziehen." & ¬
      return & return & ¬
      "Bitte Unterordner nach Möglichkeit vermeiden - bereits konvertierte MX-Dateien werden erneut konvertiert!" buttons "OK" default button 1 with icon 1
end run
-----------------------------------------------------------
on open allObjects
   -- die Globalen vorbereiten------------------------------------------
   --Header für die Fehlerliste (was - wann - wer)
   set wannWer to "MX Konvertierung Fehlerliste" & return & return & ¬
      "Erstellt am: " & (current date) & return & "Erstellt von: " & (computer name of (system info))
   set errorListe to {wannWer & return & return}
   --Errormarker auf null setzen
   set errorYes to "No"
   -- <projekt:MX schon da?>
   set allFiles to "null" --reset, wird gebraucht wenn nach einem Ordner eine einzelne Datei dran ist
   set countAll to 0
   set countConv to 0
   set countNotConv to 0
   set countIsMX to 0
   set countIsAsMX to 0
   
   if ((allObjects as text) ends with ":") then
      --------Wenn ein ganzer Ordner gedroppt wird, wird "allFiles" erstellt----------ub 1.02.08
      --------wird gebraucht, um später nach schon konvertierten fh11 Dateien zu suchen
      set allFiles to (list folder allObjects without invisibles)
      if (allFiles as text = "") then ----Marker setzen, wenn nur ein leerer Ordner gedroppt wird...
         set allFiles to "emptyFolder"
         set errorYes to "Yes"
      end if
   end if
   --------------------------------
   -- eine Wiederholungsschleife durch die gedroppten Objekte ...
   repeat with aObject in allObjects
      -- ... welche einzeln zum Handler 'processObject' geschickt werden
      processObject(aObject)
      --display dialog "!!! Variable <allObjects> im zweiten Loop: " & aObject as text
      --set countAll to countAll + 1
   end repeat
   -------------------- Counter Testdialog::
   (*
   display dialog "!!! konvertiert: " & countConv & " von " & countAll & return & ¬
      return & "!!! abgelehnt: " & countIsMX & " MX-Dateien" & return & "!!! und " & ¬
      countNotConv & " andere Dateien" & return & return & countIsAsMX & " waren schon als MX vh."
*)
   ---------------------------------------------------------------------------
   --Schlussmeldung, mit Fehlerhinweisen und Speicher-Funktion für eine Fehlerliste
   if (countConv = 0) then
      set resultText to "Keine Datei wurde konvertiert. "
   else if (countConv = 1) then
      set resultText to "Eine Datei wurde konvertiert. "
   else
      set resultText to (countConv as text) & " Dateien wurden konvertiert. "
   end if
   
   if (errorYes = "Yes") then --Schlussmeldung, wenn es Ärger gab
      if (allFiles = "emptyFolder") then --wenn nur ein leerer Ordner gedroppt wurde
         display dialog "Hallo, der Ordner ist ja leer!" & ¬
            return buttons "OK" default button 1 with icon 1 --giving up after 1
      else -----------------------------------wenn einige Dateien Ärger machten
         set countAllErrors to countNotConv + countIsMX + countIsAsMX --Fehler addieren   
         if (countAllErrors = 0) then
            set resultErrors to "Keine Datei wurde nicht konvertiert. "
         else if (countAllErrors = 1) then
            set resultErrors to "Eine Datei wurde nicht konvertiert. "
         else
            set resultErrors to (countAllErrors as text) & " Dateien wurden nicht konvertiert. "
         end if
         display dialog "Fertig. " & return & return & resultText & return & return ¬
            & resultErrors & return & ¬
            "Soll eine Liste davon gespeichert werden?" buttons {"Nein", "Speichern"} ¬
            default button 2 with icon 1
         if button returned of result = "Speichern" then
            saveErrorListe()
         end if
      end if
      
   else ----------------Schlussmeldung, wennALLE Freehandfiles konvertiert wurden
      display dialog "Fertig." & return & return & resultText & return ¬
         buttons "OK" default button 1 with icon 1 --giving up after 1
   end if
   
end open
----------------------------------------------------------------


-- der Handler, welcher die gedroppten Objekte prüft: den Inhalt von Ordnern listet er auf und schickt die Elemente an sich selbst
-- Dateien werden an den Konvertierungs-Handler weitergegeben | von Hans Haesler - CH-1018 Lausanne
on processObject(aObject)
   -- wenn der Pfad mit einem Doppelpunkt endet, ist das Objekt ein Ordner ...
   if (aObject as Unicode text) ends with ":" then
      -- die Liste der Objekte wird erstellt (ohne unsichtbare Dateien)
      set contentsList to list folder aObject without invisibles
      -- Wiederholungsschleife durch diese Liste
      repeat with anItem in contentsList
         -- der Pfad wird zusammengesetzt
         set objPath to ((aObject as Unicode text) & anItem)
         -- die Elemente (Dateien oder Ordner) werden an den aktuellen Handler geschickt
         processObject(objPath as alias)
         set countAll to countAll + 1
      end repeat
      -- ... sonst ist das Objekt eine Datei
   else
      set curFile to (aObject as Unicode text)
      -- ... den Pfad dem Handler 'printFile' übergeben
      convFile(curFile)
   end if
end processObject

-- in diesem Handler werden die Suffixe ausgewertet und -wenn Freehand 8 bis 10- in .fh11 geändert
-- Freehand MX öffnet die Datei dann und sichert sie als ".fh11"-Datei
on convFile(fhFile)
   --------testen, ob Freehand-Datei vom Mac
   set macFile to "PC"
   tell application "Finder"
      set myFile to fhFile as alias
      if (the creator type of myFile) = "FH70" or (the creator type of myFile) = ¬
         "FH80" or (the creator type of myFile) = "FH90" or (the creator type of myFile) = "FH X" then
         set macFile to "Mac"
      else if (the creator type of myFile) = "FH11" or fhFile ends with ".fh11" then
         set macFile to "FH MX"
      end if
   end tell
   --------testen, ob Freehand-Datei (Mac oder PC), wenn ja dann Dateinamen auf Freehand MX aktualisieren
   if (fhFile ends with ".fh7" or fhFile ends with ".ft7" or fhFile ends with ¬
      ".fh8" or fhFile ends with ".ft8" or fhFile ends with ".fh9" or fhFile ends with ¬
      ".ft9" or fhFile ends with ".fh10" or fhFile ends with ".ft10" or macFile = "Mac") then
      set newFileName to "null"
      if (fhFile ends with ".fh7") then
         set newFileName to textReplace(fhFile, "fh7", "fh11")
      else if (fhFile ends with ".ft7") then
         set newFileName to textReplace(fhFile, "ft7", "fh11")
      else if (fhFile ends with ".fh8") then
         set newFileName to textReplace(fhFile, "fh8", "fh11")
      else if (fhFile ends with ".ft8") then
         set newFileName to textReplace(fhFile, "ft8", "fh11")
      else if (fhFile ends with ".fh9") then
         set newFileName to textReplace(fhFile, "fh9", "fh11")
      else if (fhFile ends with ".ft9") then
         set newFileName to textReplace(fhFile, "ft9", "fh11")
      else if (fhFile ends with ".fh10") then
         set newFileName to textReplace(fhFile, "fh10", "fh11")
      else if (fhFile ends with ".ft10") then
         set newFileName to textReplace(fhFile, "ft10", "fh11")
      else if (fhFile ends with ".eps") then
         set newFileName to textReplace(fhFile, "eps", "fh11") ---betrifft nur Mac-Dateien
      else
         set newFileName to fhFile & ".fh11" -------------------betrifft nur Mac-Dateien
      end if
      ----------------Schon als Freehand MX Datei vorhanden???---------
      set tempFileName to extractFileName(newFileName) --prüfen, ob bereits als Freehand MX vorhanden,
      if ((tempFileName as text) is not in (allFiles as text)) then --wenn nicht, dann die Datei bearbeiten   
         makeTempFile(newFileName) --temporäre Datei anlegen (weil mit AppleScript kein "save as fh11" läuft)
         tell application "FreeHand MX" --Datei in Freehand öffnen, speichern und schließen
            open fhFile as alias without Dialogs --Fehlerdialoge von Freehand beim öffnen unterdrücken
            set savePath to newFileName as alias
            save document 1 in savePath
            close document 1
            set countConv to countConv + 1 ---Counter zu Testzwecken
         end tell
      else
         set shortFileName to extractFileName(fhFile) ---schon vorhanden-Fehlermeldung erstellen
         set nextError to "Datei: " & shortFileName & " --> ist schon als Freehand MX - Datei vorhanden" & ¬
            return & return
         set errorYes to "Yes"
         set errorListe to errorListe & nextError
         set countIsAsMX to countIsAsMX + 1 ---Counter zu Testzwecken
      end if
      -------------anderer Fehler: Fehlermeldung erstellen-------------------
   else
      set shortFileName to extractFileName(fhFile)
      if (macFile = "FH MX") then
         set nextError to "Datei: " & shortFileName & " --> ist schon eine Freehand MX - Datei" & return & return
         set countIsMX to countIsMX + 1 ---Counter zu Testzwecken
      else
         set nextError to "Datei: " & shortFileName & " -->ist keine Freehand - Datei" & return & return
         set countNotConv to countNotConv + 1 ---Counter zu Testzwecken
      end if
      set errorYes to "Yes"
      set errorListe to errorListe & nextError
      --display dialog (errorListe as text)
   end if
end convFile

---------------Search'n'Replace-Routine - Quelle M.K. Myers/snow@Fischer-Bayern.de
on textReplace(theText, srchStrng, replStrng)
   tell (a reference to AppleScript's text item delimiters)
      set {od, contents} to {contents, {srchStrng}}
      try
         set {textList, contents} to {(text items of theText), {replStrng}}
         set {newText, contents} to {(textList as text), od}
         return item 1 of result
      on error errMsg number errNbr
         set contents to od
         error errMsg number errNbr
      end try
   end tell
end textReplace
-----------------------------------------------------

--temporäre Dateien mit den Dateinamen der zu erstellenden Freehand MX Dateien erzeugen
--Inhalt dieser Dateien: was, wann (Datum-Urzeit) und von wem (Computer Name)
on makeTempFile(fileName)
   set RefNum to (open for access file fileName with write permission)
   write "temporaere AppleScript - Datei" & return & "erzeugt am " & (current date) & return & ¬
      "von " & computer name of (system info) to RefNum
   close access RefNum
end makeTempFile
----------------------------------------

--------Fehlerliste speichern und in TextEdit öffnen
on saveErrorListe()
   set errorListe to errorListe as text
   display dialog ¬
      "Die Fehlerliste wird auf dem Schreibtisch gespeichert." & return & ¬
      "Bitte geben Sie den Dateinamen an:" default answer ¬
      "MX Konvertierung Fehlerliste.txt" buttons {"Abrechen", "Speichern"} default button 2 with icon 1
   copy the result as list to {text_returned, button_pressed}
   if (button_pressed = "Speichern") then
      --display dialog text_returned & return & button_pressed
      set savePath to (path to desktop) & text_returned as text
      set fileNum to (open for access file savePath with write permission)
      write errorListe to fileNum
      close access fileNum
      tell application "TextEdit"
         activate
         open savePath
      end tell
   end if
end saveErrorListe
------------------------------

--------------------Dateinamen aus Pfad extrahieren-----------
on extractFileName(daPath)
   set my text item delimiters to {":"}
   set daFile to last text item of daPath as string
   set my text item delimiters to {""}
   return daFile
end extractFileName
----------------------



Jetzt bin ich mal gespannt :-)
Gruß Uli
_________________
E>0 = mc2/:-)
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden
chebfarid
•-->
•-->


Anmeldedatum: 10.02.2007
Beiträge: 106
Wohnort: Milano

BeitragVerfasst am: 09.07.2008 - 16:24    Titel: Antworten mit Zitat

Ist ulkig: ich habe gar kein Freehand, also habe ich die Zeile
tell application "Freehand MX"
in
tell application "Finder"
umbenannt, um das Script kompilieren zu können.
Um das Durcheinander noch größer zu machen, habe ich drei Jpegs auf das Droplet gezogen: das Script läuft ohne Zicken und verkündet am Ende korrekterweise, daß es keinen File konvertiert hat.
(MacBookPro OS X 10.5.2)

Die Zeile, die mir eventuell verdächtig vorkommt ist
Code:
(computer name of (system info)).
Probiert mal aus, ob der Befehl
system info
auf dem Mac Deiner Kollegin funktioniert.

Ciao
Farid
_________________
Abends lustig morgens triste
Das ist Leben von Artiste
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden Website dieses Benutzers besuchen
Uli
•-->
•-->


Anmeldedatum: 07.01.2008
Beiträge: 22
Wohnort: Hamburg

BeitragVerfasst am: 10.07.2008 - 17:04    Titel: Antworten mit Zitat

chebfarid hat Folgendes geschrieben:
Die Zeile, die mir eventuell verdächtig vorkommt ist
Code:
(computer name of (system info)).
Probiert mal aus, ob der Befehl system info auf dem Mac Deiner Kollegin funktioniert.


Danke für’s Ausprobieren Farid,
und schön zu wissen, das es bei Dir läuft.

Der Befehl (computer name of (system info)) dauert bei mir beim ersten Scriptaufruf ganz schön lange, dannach kommt das Ergebnis immer sofort....

Ich habe mal ein kleines Testscript nach Österreich geschickt, die Gute scheint aber gerade Urlaub zu machen -
ich melde mich wieder, wenn ich das Ergebnis habe.

Viele Grüße
Uli
_________________
E>0 = mc2/:-)
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden
Uli
•-->
•-->


Anmeldedatum: 07.01.2008
Beiträge: 22
Wohnort: Hamburg

BeitragVerfasst am: 14.07.2008 - 18:13    Titel: Antworten mit Zitat

Uli hat Folgendes geschrieben:

Ich habe mal ein kleines Testscript nach Österreich geschickt, die Gute scheint aber gerade Urlaub zu machen - ich melde mich wieder, wenn ich das Ergebnis habe.

Jetzt rede ich schon mit mir selber . . . :-)

So, die Gute ist wieder im Lande, hat das Testscript getestet und folgende Meldung bekommen:

Laufzeitfehler
<<script>> doesn´t understand the <<event
sysosigt>> message

und ein Button "Stop" drunter


Kann das wer irgendwie deuten?

Danke und Gruß
Uli
_________________
E>0 = mc2/:-)
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden
chebfarid
•-->
•-->


Anmeldedatum: 10.02.2007
Beiträge: 106
Wohnort: Milano

BeitragVerfasst am: 14.07.2008 - 18:43    Titel: Antworten mit Zitat

Das einzige, was sich ergoogeln läßt, ist daß es sich um eine Unkompatibilität mit OS X 10.3 handelt.
Das bedeutet an einer Stelle in Deinem Script befindet sich Code, den Panther nicht verarbeiten kann.

Ciao
Farid
_________________
Abends lustig morgens triste
Das ist Leben von Artiste
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden Website dieses Benutzers besuchen
Beiträge der letzten Zeit anzeigen:   
Neues Thema eröffnen   Neue Antwort erstellen    Fischer-Bayern.de Foren-Übersicht -> AppleScript X Alle Zeiten sind GMT + 2 Stunden
Seite 1 von 1

 
Gehe zu:  
Du kannst keine Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum nicht antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.


Powered by phpBB © 2001, 2002 phpBB Group
Deutsche Übersetzung von phpBB.de


AppleScript für absolute Starter